On a related topic, if you wanted to convert a Scalable Vector Graphics (SVG) image to PDF, you could proceed as follows.
1) Create a directory, SvgToPdf, under ColdFusion's web root. Create the subdirectory, lib, in SvgToPdf.
2) Download the FOP library,
fop-2.5-bin.zip
from https://xmlgraphics.apache.org/fop/download.html and unzip it.
3) Copy the following JAR files to the directory /SvgToPdf/lib/
fop-2.5-bin\fop-2.5\fop\build\fop.jar
fop-2.5-bin\fop-2.5\fop\lib\batik-all-1.13.jar
fop-2.5-bin\fop-2.5\fop\lib\commons-io-1.3.1.jar
fop-2.5-bin\fop-2.5\fop\lib\xmlgraphics-commons-2.4.jar
That is, on your system, their paths should be, respectively,
/SvgToPdf/lib/fop.jar
/SvgToPdf/lib/batik-all-1.13.jar
/SvgToPdf/lib/commons-io-1.3.1.jar
/SvgToPdf/lib/xmlgraphics-commons-2.4.jar
They are the libraries to be used for the SVG to PDF conversion. We need to inject them into ColdFusion.
We shall use the javasettings property to do so. Therefore, create within the directory SvgToPdf an Application.cfc file having the following content:
<cfcomponent displayname="Application" output="true" hint="Handle the application.">
<!--- Set up the application. --->
<cfset this.Name = "SVG2PDF" />
<cfset this.ApplicationTimeout = createTimeSpan( 1, 0, 0, 0 ) />
<cfset this.sessionTimeout = createTimeSpan( 0, 0, 30, 0 ) />
<cfset this.sessionManagement = true />
<cfset this.javaSettings = {LoadPaths = [ "#expandPath(".")#\lib"]}>
<cffunction
name="OnApplicationStart"
access="public"
returntype="boolean"
output="false"
hint="Fires when the application is first created.">
<cfreturn true />
</cffunction>
</cfcomponent>
4) Within the directory SvgToPdf, create a CFM page, generatePdfFromSvg.cfm. It contains the following code:
<cfscript>
// The input and output
inputFilePath = expandPath("1607519675floral_pattern_geometric.svg");
outputFilePath = expandPath("outputDoc.pdf");
// Transcode the SVG input
inputFile = createobject("java", "java.io.File").init(inputFilePath);
fileInputStream = createobject("java", "java.io.FileInputStream").init(inputFile);
transcoderInput = createobject("java", "org.apache.batik.transcoder.TranscoderInput").init(fileInputStream);
// Create the output stream
outputFile = createobject("java", "java.io.File").init(outputFilePath);
fileOutputStream = createobject("java", "java.io.FileOutputStream").init(outputFile);
// Transcode the input into the output
PDFTranscoder = createobject("java", "org.apache.fop.svg.PDFTranscoder").init();
transcoderOutput = createobject("java", "org.apache.batik.transcoder.TranscoderOutput").init(fileOutputStream);
PDFTranscoder.transcode(transcoderInput, transcoderOutput);
// Close the streams to release fle-system resources
fileInputStream.close();
fileOutputStream.close();
</cfscript>
<cfheader name="Content-Disposition" value="inline;filename=#outputFilePath#">
<cfcontent type="application/pdf" file="#outputFilePath#" deleteFile="no" />
5) Launch the file generatePdfFromSvg.cfm
10
Replies
AdChoices