Background Music with On/Off Button

Hi.

It will be better to call your song from the Library and control it with corresponding AS3 classes. Like this:

AS3 code:

import flash.events.MouseEvent;
import flash.media.SoundChannel;
import flash.media.SoundTransform;

if (!this.frame1Started)
{
	var channels:Object = {};
	var bgmIsPlaying:Boolean = true;

	toggleButton.addEventListener(MouseEvent.CLICK, toggleBGM);
	// BGM is the linkage name of a sound file in the Library.
	// "bgm" is a name you give for the channel you want your song to play on. If you need to play simultaneous sounds, give them different channels names
	// 1 is the volume. The acceptable range is from 0 to 1
	// 9999 is number of times the song will loop
	playSound(new BGM(), "bgm", 1, 9999);
	this.frame1Started = true;
}

function playSound(sound:*, channel:String, volume:Number = 1, loops:uint = 0):void
{
	var soundTransform:SoundTransform = new SoundTransform();
	
	if (!channels[channel])
		channels[channel] = new SoundChannel();

	channels[channel] = sound.play(0, loops);
	soundTransform.volume = volume;
	channels[channel].soundTransform = soundTransform;
}

function stopSound(channel:String):void
{
	if (channels[channel])
		channels[channel].stop();
}

function toggleBGM(e:MouseEvent):void
{
	if (bgmIsPlaying)
		stopSound("bgm");		
	else
		playSound(new BGM(), "bgm", 1, 9999);
	
	bgmIsPlaying = !bgmIsPlaying;
}

FLA / sample / files:

https://bit.ly/3hGUGNP

Please let us know if you need further assistance.

Regards,

JC