Best way to animate this "complex" circular menu

Hi.

I'm not sure if this is exactly what you want, but here is a sample that I hope will get you started:

AS3 code:

import fl.motion.easing.*;
import fl.transitions.Tween;
import flash.events.MouseEvent;
import flash.display.MovieClip;
import flash.display.DisplayObject;
import fl.transitions.TweenEvent;
import flash.display.SimpleButton;
import flash.display.Sprite;

function spinMenu(e:MouseEvent):void
{
	var index:uint = (e.currentTarget as MovieClip).getChildIndex(e.target as DisplayObject);
	var tween = new Tween(e.currentTarget, "rotation", Sine.easeInOut, e.currentTarget.rotation, -30 * index, 0.5, true);
	
	tween.addEventListener(TweenEvent.MOTION_CHANGE, motionChange);
}

function motionChange(e:TweenEvent):void
{
	var i:uint;
	
	for (i = 0; i < menu.numChildren; i++)
	{
		var button:SimpleButton = menu.getChildAt(i) as SimpleButton;
		var upState:Sprite = button.upState as Sprite;
		var overState:Sprite = button.overState as Sprite;
		var downState:Sprite = button.downState as Sprite;
		
		(upState.getChildAt(1) as DisplayObject).rotation = -menu.rotation;
		(overState.getChildAt(1) as DisplayObject).rotation = -menu.rotation;
		(downState.getChildAt(1) as DisplayObject).rotation = -menu.rotation;
	}
}

menu.addEventListener(MouseEvent.CLICK, spinMenu);

FLA / code / source / files:

https://github.com/joao-cesar/adobe/tree/master/animate%20cc/as3/circular_menu

If you don't want to update the text fields rotation, just remove the line that adds the event listener for the motion change.

I hope this helps.

Regards,

JC