Dynamically Load Bitmaps from SWC

I looked into dynamically loading SWC libs awhile back, and I came up with this. While it functions, it is by no means complete. But you should be able to gleen something from it.

// requires AS3 zip library from nochump.com
// http://www.nochump.com/blog/?p=15

import flash.utils.IDataInput;
import nochump.util.zip.*;

var swcPath:String = "MyImageLibrary.swc";

// we need a Loader instance to write the uncompressed library bytes to
var libLoader:Loader = new Loader();
libLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, libLoadCompleteHandler);

// load the swc
var urlLoader:URLLoader = new URLLoader()
urlLoader.dataFormat = URLLoaderDataFormat.BINARY;

var request:URLRequest= new URLRequest(swcPath);
urlLoader.addEventListener(Event.COMPLETE, swcLoadCompleteHandler);
urlLoader.load(request);

function swcLoadCompleteHandler(event:Event)
{
var loadedData:IDataInput = event.target.data as IDataInput;

var zipFile:ZipFile = new ZipFile(loadedData);

// this example assumes there is only one swf file
// in the swc :  library.swf
// would be safer to parse catalog.xml
for(var i:int = 0; i < zipFile.entries.length; i++)
{    
  var entry:ZipEntry = zipFile.entries;    
  var data:ByteArray = zipFile.getInput(entry);  
 
  if(entry.name =="catalog.xml")
  {
   // we'll do nothing in this example
  }
  if(entry.name =="library.swf")
  {
   // load the library
   libLoader.loadBytes(data);
  }
}
}

function libLoadCompleteHandler(event:Event):void
{
var dom:ApplicationDomain = libLoader.contentLoaderInfo.applicationDomain;
try
{
  var bmpClass:Class = dom.getDefinition("Image000") as Class;
  if(bmpClass != null)
  {
   var bmp:Bitmap = new Bitmap();
  
   // need to pass 2 arguments to a BitmapData ctor
   bmp.bitmapData = new bmpClass(1,1) as BitmapData
   this.addChild(bmp);
  }
 
}
catch(e)
{
  trace(e);
}
}