Image Gallery Issue in As3

Here is a code that should work for you. Note that it is a stripped version of a class code, so while removing class related items, some bugs may be introduced. When in class code worked perfectly.

import flash.display.DisplayObject;
import flash.display.Loader;
import flash.events.Event;
import flash.events.TimerEvent;
import flash.net.*;
import flash.utils.Timer;
import gs.TweenLite;
     
var xmlURL:String = "http://www.creative-showcase.co.uk/BirdStudiosOld/Videos/test/images.xml";
// array of loaded images
// you don't have to reload them every time
// unless you want to free memory
// which will involve additional coding
// and more complex logic
var loadedImages:Array = [];
// array of images urls
var imageURLs:Array = [];
// image loader
var imageLoader:Loader;
// previously displayed image
var prevImage:DisplayObject;
// current image
var currentImage:DisplayObject;
// slide show timer
var showTimer:Timer;
// timer duration
var timerDuration:int = 3000;
// tween duration
var tweenDuration:int = 2;
// index of the current slide
var currentIndex:int = 0;

var myXMLURL:URLRequest = new URLRequest(xmlURL);
var xmlLoader:URLLoader = new URLLoader(myXMLURL);
xmlLoader.addEventListener(Event.COMPLETE, xmlLoaded);
xmlLoader.load(myXMLURL);

function xmlLoaded(e:Event):void 
{
     // allow for GC
     e.target.removeEventListener(Event.COMPLETE, xmlLoaded);
     processXML(XML(e.target.data));
}

function processXML(xml:XML):void {
     var len:int = xml.children().length();
     // declare variable once
     var tempVar:String;
     for (var i:int = 0; i < len; i++) {
          tempVar = "http://www.creative-showcase.co.uk/BirdStudiosOld/Videos/test/" + xml..item..image;
          imageURLs.push(tempVar);
     }
     preload();
}

function preload():void
{
     // preload the rest of the images
     // in this case the logic is that
     // because slide show is automatic
     // it may make sense to have all of them
     // in memory - they are going to be there 
     // eventually anyway
     var len:int = imageURLs.length;
     for (var i:int = 0; i < len; i++) {
          imageLoader = new Loader();
          imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onPreloadComplete);
          // hold loader in the array - it will be reused
          loadedImages.push(imageLoader);
          imageLoader.load(new URLRequest(imageURLs));
     }     
}

function onPreloadComplete(e:Event):void 
{
     // prepare for GC
     e.target.removeEventListener(Event.COMPLETE, onPreloadComplete);
     // if timer is not instantiated - show is not started
     // AND first two were preloaded - meaning they have content
     if (!showTimer && loadedImages[0].content &&   loadedImages[1].content ) startShow();
}

function startShow():void
{
     // place first image on display list
     currentImage = loadedImages[0];
     currentImage.alpha = 0;
     addChild(currentImage);
     TweenLite.to(currentImage, 1, { alpha: 1 } );
     // start show timer
     showTimer = new Timer(timerDuration);
     showTimer.addEventListener(TimerEvent.TIMER, slideTransition);
     showTimer.start();
}

function slideTransition(e:TimerEvent):void 
{
     // in case sequence is important - don't change 
     // current index yet but check against
     // separate variable
     var nextImage:int = currentIndex < loadedImages.length - 1 ? currentIndex + 1 : 0;
     // check if image was loaded
     // if it is not loaded - will wait until next timer event round
     if (loadedImages[nextImage].content) {
          // now we can change current index
          currentIndex = nextImage;
          // place it behind current image
          addChildAt(loadedImages[currentIndex], getChildIndex(currentImage));
          // swap them
          prevImage = currentImage;
          currentImage = loadedImages[currentIndex];
          // show transition
          showCurrent();
     }
}

function showCurrent():void
{
     // make sure they have proper alphas
     prevImage.alpha = 1;
     currentImage.alpha = 0;
     TweenLite.to(prevImage, tweenDuration, { alpha: 0 } );
     TweenLite.to(currentImage, tweenDuration, { alpha: 1, onComplete: removePrevious } );
}

function removePrevious():void {
     if (this.contains(prevImage)) removeChild(prevImage);
}