load swf into RAM via an asset manager

Hi Andrei, nice to see you around here.

Well, somebody helping me says that normally we make a http request with urlLoader to the server and that is what was happening each time. We weren't getting the cached swf. (that bit I don't understand and doesn't sound right - anyway...)

So he says if we create a dictionary class to hold that swf then the next time we make a request we will get the movie from there and not from the server.

I have highlighted the main parts of code below.

What I don't understand about all this is that I have never seen anything like this in my life. I have read extensively and read all about loading external files and using this type of asset manager with the dictionary class does not ring a bell and goole comes up with nothing.

I hunch is that as you say, we are doing something wrong somewhere because the only way to get an external file is via urlLoader to the server the first time and then the second time it should look for it cached on our computer is that right? Or when we make the urlLoader request how does it know to look on our computer first before going to the server or are these innner workings of the flash player I know nothing about. This is so important as when I get 10 kids on the computers they wait for as long as 5 minutes for movies that have already been downloaded many times before.

Cheers in advance.

package com.Gerry.managers.assetManager

{

    import flash.display.Loader;

    public class AssetLoader extends Loader

    {

        private var _assetName:String;

        public function AssetLoader()

        {

            super();

        }

        public function get assetName():String

        {

            return _assetName;

        }

        public function set assetName(value:String):void

        {

            _assetName = value;

        }

    }

}

--------------------------------------------------------------------------------------------------

The asset manager loading class

package com.Gerry.managers.assetManager

{

    import flash.display.Loader;

    import flash.display.LoaderInfo;

    import flash.display.MovieClip;

    import flash.display.Sprite;

    import flash.events.Event;

    import flash.net.URLRequest;

    import flash.utils.Dictionary;

    public class AssetManager extends Sprite

    {

        public static const ASSET_LOADED:String = "assetLoaded";

        private static var _instance:AssetManager;

        private var _assetsLoaded:Dictionary = new Dictionary();

        private var _assetsBeingLoaded:Dictionary = new Dictionary();

        public function AssetManager(pvt:SingletonEnforcer)

        {

        }

        /**

         * loads and asset and keeps a reference to the loaded content

         * @param name

         * @return null if the asset is not loaded yet

         *

         */

       public function loadAsset(name:String):MovieClip

        {

            var asset:MovieClip;

            if (_assetsLoaded[name])

            {

                asset = _assetsLoaded[name];

            }

            else if (_assetsBeingLoaded[name] == null)

            {

                var skinloader:AssetLoader = new AssetLoader();

                skinloader.assetName = name;

                skinloader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadCompleteF);

                skinloader.load(new URLRequest(name));

                _assetsBeingLoaded[name] = true;

            }

            return asset;

        }

        protected function loadCompleteF(e:Event):void

        {

            var skin:MovieClip = e.target.content as MovieClip;

            var name:String = ((e.target as LoaderInfo).loader as AssetLoader).assetName;

            _assetsLoaded[name] = skin;

            delete _assetsBeingLoaded[name];

            dispatchEvent(new Event(ASSET_LOADED));

        }

        /**

         * gets an instance of the class

         * @return

         *

         */

        public static function get instance():AssetManager

        {

            if (_instance == null)

            {

                _instance = new AssetManager(new SingletonEnforcer());

            }

            return _instance;

        }

    }

}

internal class SingletonEnforcer

{

}

-------------------------------------------------------------------------------------------------------------------------------------------

The function inside a class called Screen which is used by menus classes to load their swf menus.

protected function loadSkin(path:String = null):void

        {

            trace("skin to load: " + path);

            Home.instance.addPreloaderF();

            _path = path + Home.instance.cacheString;

            if (_usingAssetManager)

            {

                loadSkinFromAssetManager();

            }

            else

            {

                if (_skinloader.content)

                {

                    _skinloader.unloadAndStop(true);

                }

                _skinloader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadCompleteF);

                _skinloader.load(new URLRequest(_path));

            }

        }

        protected function loadSkinFromAssetManager(e:Event = null):void

        {

            _skin = AssetManager.instance.loadAsset(_path);

            //if no skin we have to wait to be loaded it

            if (_skin == null)

            {

                AssetManager.instance.addEventListener(AssetManager.ASSET_LOADED, loadSkinFromAssetManager);

            }

            else

            {

                AssetManager.instance.removeEventListener(AssetManager.ASSET_LOADED, loadSkinFromAssetManager);

                loadCompleteF(null);

            }

        }