Possible Memory Leak with stageVideo?

"Scenario 1: For both software and stage video, re-using the netconnection and netstream objects results in no memory loss."

So, it does look like there is no inherent to StageVideo memory leaks and everything about making sure that objects are eligible for GC

"Scenario 3: ... The parent unloads the child (with the unloadAndStop method) and then reloads the child to start the movies over again."

Why would you do that in actual application? The whole point of OOP is reusing of objects.

Andrei1,

You are absolutely right here! The best thing to do would be to re-use the netconnection, netstream and metalistener objects.

What I hadn't mentioned in my first post is that this code was taken from a larger more complex project where some swfs dynamically others, each of which performs some operation. In this case, we are loading a swf which plays one or more videos, cleans itself up and then communicates to the parent swf so the child may be completely unloaded. In order to make this post more simple, I pulled out the movie code and modified it to be a stand-alone swf. In doing so, I had missed moving some of my "removeEventListeners". I went ahead and fixed my test swf to reflect your suggestions, and sure enough the memory usage remains constant.

However, here's my challenge:

Because this project is modular, I would like a movie swf to be able to create netconnections and netstreams, use them, and then clean them up. Of course, I could store those objects in parent swfs and have the dynamically loaded swfs reference the objects contained in the parent. However, I would like to see if these can be done as atomic operations within each child swf. Again, if I do all the decoding in software, the resources clean up fine. If I use stageVideo, the memory leak starts.

So, to emulate the atomic operation of a dynamically loaded swf, I am re-creating the netconnection, netstream and metalistener object. I try cleaning them up with the following:

        stageVideo.removeEventListener(StageVideoEvent.RENDER_STATE, onStageVideoEvent);
        stage.removeEventListener(StageVideoAvailabilityEvent.STAGE_VIDEO_AVAILABILITY, onStageVideoState);
        stageVideo.viewPort = new Rectangle(0,0,0,0);
        stageVideo.attachNetStream(null);
        stageVideo = null;   
        netStream.removeEventListener(NetStatusEvent.NET_STATUS, netStreamStatus);
        netStream.removeEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
        netStream.client = {};
        metaListener  = null;
        netStream.close();       
        netStream = null;
        videoConnection.close();
        videoConnection = null;

Still, on the next iteration the memory is never released. I tested the swf again with the FlexProfiler and it shows me that the flash player memory utilization is constant even though the operating system shows that memory usage is increasing.

Am I missing something?

I modified the leaky code slightly to place the resource clean up in its own function (before it was in the netstatus function). The full code follows.

Thanks again for taking the time to help me out!

Josh

package
{

    import flash.display.*;
    import flash.events.*;
    import flash.net.*;
    import flash.utils.*;
    import flash.media.*;
    import flash.geom.*;
   
    public class stageVideoMemoryTest3 extends MovieClip
    {
        var duration:uint=0;
        var reload:Boolean = false;   
        var timer4:Timer;
        var movieArray:Array;
        var urlArray:Array;
        var curr:uint = 0;
        var playmenow:String;
        var orig_width:Number;       
        var orig_height:Number;
        var aspect:Number;
        var containerAspect:Number;       
        var netStream:NetStream;
        var containerWidth:Number;
        var containerHeight:Number;
        var videoConnection:NetConnection;
        var videoFinished:uint = 0;
        var stageVideoAvailable:Boolean;
        var stageVideo:StageVideo;
        var videoWidth:uint;
        var videoHeight:uint;
        var videoX:uint = 0;
        var videoY:uint = 0;
        var v:Vector.<StageVideo>;
        var metaListener:Object
       
        public function stageVideoMemoryTest3()
        {

        trace("stageVideoMemoryTest3 has been instantiated");
        curr = 0;
        // screen size
        containerWidth = 1080;
        containerHeight = 1920;
       
        this.blendMode = BlendMode.LAYER;
        stage.scaleMode = StageScaleMode.NO_SCALE;
        stage.align = StageAlign.TOP_LEFT;
       
        v = stage.stageVideos;
        if ( v.length >= 1 ) {
        stageVideoAvailable = true;       
        stage.color = 0x000000;
        trace("StageVideo available. Number of instances: " + v.length);        
        } else {
        stageVideoAvailable = false;
        trace("StageVideo is unavailable.");
        }

        movieArray = new Array();
        movieArray.push("http://localhost/cabana_arch.mov");
        movieArray.push("http://localhost/bluezoo_arch.mov");
        movieArray.push("http://localhost/fountain_burger.mov");
        playMovies();
        // end Constructor
        }
               
       
        public function playMovies():void
        {
        trace("playMovies called");
       
        try {
        videoConnection = new NetConnection ();
        videoConnection.connect(null);
        netStream = new NetStream(videoConnection);
        metaListener = new Object();
        metaListener.onMetaData = onMetaData;
        netStream.client = metaListener;   
        } catch(e:Error) {
        trace("Unable to create netstream connection");   
        }
               
        playmenow = movieArray[curr];
        trace("We are going to play the following movie: " + playmenow);
       
        stageVideo = v[0];
        stageVideo.attachNetStream(netStream);
        stageVideo.addEventListener(StageVideoEvent.RENDER_STATE, onStageVideoEvent);
        stage.addEventListener(StageVideoAvailabilityEvent.STAGE_VIDEO_AVAILABILITY, onStageVideoState);   
        netStream.play(playmenow);
        netStream.addEventListener(NetStatusEvent.NET_STATUS, netStreamStatus);
        netStream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

   
        // close playmovie
        }
               
               
        function asyncErrorHandler(event:AsyncErrorEvent):void
        {
        trace("asyncErrorHandler called: " + event.text);
        }        
               
               
               
               
        function onMetaData(data:Object):void
        {
        trace("onMetaData function called!!");   
       
            duration = data.duration;
            netStream.bufferTime = 1;
            // aspect ratio corrections
            orig_width = data.width;
            orig_height = data.height;
            aspect = orig_width/orig_height;
            containerAspect = containerWidth/containerHeight;       
                       
            if ((aspect > containerAspect) && ((aspect-containerAspect)/containerAspect > 0.107)) {
            // trace("film aspect is wider by more than 10%");
            // the film has a wider aspect ration than the container by more than 10.7%. Let's take the container's width as the video's width (possible letter box)           
            videoWidth = containerWidth;
            // now set the height based on the original ratio
            videoHeight = videoWidth/aspect;
            }
           
            if ((aspect < containerAspect) && ((containerAspect-aspect)/aspect > 0.107)) {
            // trace("film is heigher by more than 10%");   
            // the film has a heigher aspect ration than the container. Let's take the container's height as the video's width (possible pill box)
            videoHeight = containerHeight;
            // now set the height based on the original ratio
            videoWidth = videoHeight*aspect;
            }

            if ( (aspect == containerAspect) || ( (aspect > containerAspect) && ( (aspect-containerAspect)/containerAspect <= 0.107) ) ||  ( (aspect < containerAspect) && ((containerAspect-aspect)/aspect <= 0.107) ) )
            {   
            // trace("video and container have essentially the same aspect ratio");
            // the video and container have the same aspect ratio, or are at least within 10% of eachother
            videoWidth = containerWidth;
            videoHeight = containerHeight;
            }
           
            if (containerWidth-videoWidth >0)
            // container is wider, we need a pill box -> center video in x axis
            {
            // trace("we need to pill box this thing");   
            videoX = ((containerWidth-videoWidth)/2);
            videoY = 0;
            }
           
            if (containerHeight-videoHeight > 0)
            {
            // trace("we need to letter box this thing");
            // container is higher, we need a letter box -> center video in y axis   
            videoY = ((containerHeight-videoHeight)/2);
            videoX = 0;
            }
            if (containerWidth == videoWidth && containerHeight == videoHeight) {
            videoX = 0;
            videoY = 0;
            }
            stageVideo.viewPort = new Rectangle(videoX,videoY,videoWidth,videoHeight);       
            trace("ViewPort params: width -> " + videoWidth + ", height -> " + videoHeight);
        // close onMetaData   
        }       
               
                   
               
        function onCuePoint(infoObject:Object):void
        {
            trace("cue point");
        }
                                       
               
       
        function onStageVideoState(event:StageVideoAvailabilityEvent):void
        {    
        trace("===============>>>>>>>><<<<<<========================");
        toggleStageVideo(event.availability == StageVideoAvailability.AVAILABLE);
        trace("===============>>>>>>>><<<<<<========================");
        }            
       
           
        function toggleStageVideo(on:Boolean):void    
        {
            if (on) {
                trace("StageVideo has become available.");
            } else {
                trace("StageVideo has become UNAVAILABLE.");
            }
        }
               
               
        function onStageVideoEvent(event:StageVideoEvent) {
        trace("===============>>>>>>>><<<<<<========================");   
        trace("STAGEVIDEO Event: " + event.status);
        trace("===============>>>>>>>><<<<<<========================");   
        // end onStageVideoEvent
        }               
               
               
               
    function netStreamStatus(e:NetStatusEvent):void
        {
                                   
            if(e.info.code == "NetStream.Play.Stop")
            {
            trace("----------------------------------------------------");   
            trace("!!!!!!!!!!!!!!! THE VIDEO IS DONE!!!! !!!!!!!!!!!!!");
            trace("----------------------------------------------------");       
                           
                curr++;
                if (curr >= movieArray.length)
                {
                    curr = 0;
                }
                trace ("Switching movie");   
                switchMovie();
               
            // end stop detected (NetStream.Play.Stop)
            }
        // end netstream status   
        }           
   
   
    function switchMovie():void {
       
        stageVideo.removeEventListener(StageVideoEvent.RENDER_STATE, onStageVideoEvent);
        stage.removeEventListener(StageVideoAvailabilityEvent.STAGE_VIDEO_AVAILABILITY, onStageVideoState);
        stageVideo.viewPort = new Rectangle(0,0,0,0);
        stageVideo.attachNetStream(null);
        stageVideo = null;   
        netStream.removeEventListener(NetStatusEvent.NET_STATUS, netStreamStatus);
        netStream.removeEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
        netStream.client = {};
        metaListener  = null;
        netStream.close();       
        netStream = null;
        videoConnection.close();
        videoConnection = null;
       
        playMovies();
       
       
    }
   
   
    // class   
    }
// package   
}