Scaling down the size of an SWF even more

No problem. I show you how.

Yeah. It is as good. The only thing you'll have to check if DeviantArt allows access from external sources. I guess it shouldn't be a problem though.

Notice in my examples I'm getting the sounds from various sources: YouTube assets library, Google Drive, my own website and even from the local file system.

You can choose whatever works best for you.

Just please make sure to check if you can use direct links to Google Drive assets (I used a online direct link generator to get direct access to the mp3 instead of using that default link type that Google Drive provides) as I'm using here. Because this example is just for learning purposes and I don't know if it is allowed to real cases usage.

Also, you cannot put your MP3 in the YouTube library. I'm using a YT song here just to showcase the possibilites.

You can totally ignore the SoundPlayer code if you wish. Only use the SoundPlayer.as file to play your sounds as in the example below.

FLA download:

animate_cc_as3_play_online_sounds.zip - Google Drive​

AS3 code:

FLA:

import flash.events.MouseEvent;
var bgmList:Vector.<String> = new <String>
[
     "https://www.youtube.com/audiolibrary_download?f=m&vid=af6b6c82fcfa686f",
     "https://drive.google.com/uc?export=download&id=1vSBKNCT87z78yfkJIb9JvoTaAV5PPv2V",
     "bgm/Stuff.mp3",
     "https://joaocesar.000webhostapp.com/adobe/Gas_Pedal.mp3"
];
function mouseHandler(e:MouseEvent):void
{
     if (e.type == MouseEvent.CLICK)
     {
          if (e.target)
               SoundPlayer.playSound(bgmList[uint(e.target.name.replace("button", ""))], "bgm");
     }
}
button0.addEventListener(MouseEvent.CLICK, mouseHandler);
button1.addEventListener(MouseEvent.CLICK, mouseHandler);
button2.addEventListener(MouseEvent.CLICK, mouseHandler);
SoundPlayer.playSound(bgmList[3], "bgm");

SoundPlayer.as:

package
{
     import flash.display.MovieClip;
     import flash.display.SimpleButton;
     import flash.events.MouseEvent;
     import flash.media.Sound;
     import flash.media.SoundChannel;
     import flash.media.SoundTransform;
     import flash.net.URLRequest;
     import flash.utils.setTimeout;
     public class SoundPlayer
     {
          public static var bgmChannel:SoundChannel = new SoundChannel();
          public static var sfxChannel:SoundChannel = new SoundChannel();
          public static function playSound(path:String, channelType:String, volume:Number = 1, start:Number = 0, loops:int = 0):void
          {
               var sound:Sound = new Sound();
               var sTransform:SoundTransform = new SoundTransform();
               sound.load(new URLRequest(path));
               if (channelType == "bgm")
               {
                    bgmChannel.stop();
                    bgmChannel = sound.play(start, loops);
                    sTransform.volume = volume;
                    bgmChannel.soundTransform = sTransform;
               }
               else if (channelType == "sfx")
               {
                    sfxChannel.stop();
                    sfxChannel = sound.play(start, loops);
                    sTransform.volume = volume;
                    sfxChannel.soundTransform = sTransform;
               }
          }
     }
}

I hope this helps.

Regards,

JC