User generated file?

Yes. You need Flash Player 10 or later.

A quick example:

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.MouseEvent;
    import flash.net.FileReference;

    public class ClickToSaveAFile extends Sprite {
        private var _filereference:FileReference;
        
        public function ClickToSaveAFile():void {
            stage.addEventListener(MouseEvent.CLICK, click);
        }
        
        private function click(e:MouseEvent):void {
            saveTextFile();
        }
        
        private function saveTextFile():void {
            _filereference = new FileReference();
            _filereference.addEventListener(Event.COMPLETE, fileSaveComplete, false, 0, true);
            _filereference.addEventListener(Event.CANCEL, fileSaveCancel, false, 0, true);
            _filereference.addEventListener(IOErrorEvent.IO_ERROR, fileSaveError, false, 0, true);
            _filereference.save("Hello world!", "example.txt");
        }
        
        private function fileSaveComplete(e:Event):void {
            trace("File saved.");
            _filereference = null;
        }
        
        private function fileSaveCancel(e:Event):void {
            trace("File save cancelled.");
            _filereference = null;
        }
        
        private function fileSaveError(e:IOErrorEvent):void {
            trace("File save error:", e.text);
            _filereference = null;
        }
    }
}