ColdFusion safe-navigation-operator used like boolean

Paolo, some good news is that there is a very simply single tweak that will get your code working.

First, though, I don't think you'll have found that code to have ever worked (as you expect) in any CF version, right? To be clear, the result of using the safe nav operator has never itself been a boolean. It's always been an "undefined" result (if the operator on the right doesn't exist). And it's because of this that your error occurs, because of course an IF test expects an expression which evaluates to boolean. 

You can even prove this without all your code (there's nothing about your if being in a method that changes things). This first example shows how the dump of the result is indeed "undefined":

<cfscript>
params = {field1 = true};
writedump(params?.field2);
</cfscript>

Then as for trying to use the result as a boolean, this next example shows (more simply) how doing that fails with the same error you show:

<cfscript>
params = {field1 = true};
if (params?.field2) {
    writeOutput("entra");
    }
</cfscript>

Finally, if you're wanting your code to "run" even if that field2 is undefined, you could tweak it simply by adding the elvis operator to the end of the line, which tells CF that if the result of the expression is indeed undefined, then it should be set to a default provided on the right side of the elvis operator. Tweaking my example above, this outputs your string:

<cfscript>
params = {field1 = true};
if (params?.field2?: true) {
    writeOutput("entra");
    }
</cfscript>

And implementing that in your code requires changing only that if line:

<cfscript>
params = {
  field1 = true
};

foo(args=params);

void function foo(required struct args) {
  if (arguments.args?.field2?:true) {
    writeOutput("entra");
  } else {
    writeOutput("non entra");
  }
}
</cfscript>

And it outputs the "entra" string. Of course, if you prefer it to return the "non entra" string, change the if line to end with false instead.

Let us know what you think.