Using CFHTTP to access a site and click on a download button...

You, sir, are lucky I'm bored and the boss isn't looking

<!--- Create a connnection to your Exchange server --->

<cfexchangeconnection connection="con" protocol="HTTPS" server="#serverIp#" action="open" username="#username#" password="#password#" />
  <!--- Get a query object of any emails that match the subject line --->
  <cfexchangemail action="get" connection="con" name="qEmails">
    <cfexchangefilter name="subject" value="Whatever your Subject Line is">
</cfexchangemail>
<cfexchangeconnection connection="con" action="close" />

<!--- If we found emails matching the subject line, --->
<cfif qEmails.recordcount >
    <!--- Loop through each email found, as there may be more than one --->
    <cfloop query="qEmails">
        <!--- Get the content of the message, assuming there's a plain text part --->
        <cfset thisContent = qEmails.message />
       
        <!--- Find the index of the string starting "http://" --->
        <cfset httpIndexChar = find("http://",thisContent) />
        <!--- Find the index of the word ".php" and add four to *include* the ".php" --->
        <cfset firstPhpIndexChar = find(".php",thisContent) + 4 />
        <!--- Do the same again from that point, as the URL has two ".php" parts --->
        <cfset secondPhpIndexChar = find(".php",thisContent,firstPhpIndexChar) + 4 />
       
        <!--- Calculate the length of the URL, so we can strip it out --->
        <cfset urlLength = secondPhpIndexChar - httpIndexChar >
       
        <!--- Strip down the message content to only the characters between those two values,
                this should now be the valid URL in the email --->
        <cfset theURL = mid(thisContent,httpIndexChar,urlLength) />

        <!--- Create an HTTP connection to the URL and get back a struct of its content --->         
        <cfhttp url="#theUrl#" result="httpContent" />
       
        <!--- You now have a struct called HTTPCONTENT.filecontent which contains the HTML from the page.
                You need to strip this down using methods similar to above, except the service
                in question is currently down, so I can't test it --->
       
    </cfloop>
</cfif>

As I've put in there the service is down at the moment so I can't actually do the second part, but it's more or less the same as the first part - try to find some simple and consistent rules as to where on the page the link will be, strip it, do another CFHTTP to get that file, then CFFILE to write it to disk.

Hope that helps, I'm off for a monster coffee.

O.