Flash interprets 3xx redirect responses as errors.

HI, i'm currently facing tha same issue, succesfull uploads but a non usable response object from event:

[HTTPStatusEvent type="httpStatus" bubbles=false cancelable=false eventPhase=2 status=302 responseURL=null]

Did u ever solved it or found a solution for this?

this is my actual code:

package com.theguaz {

    import flash.display.*;

    import flash.events.*;

    import flash.net.*;

    import flash.system.*;

    import flash.external.ExternalInterface;

    import com.adobe.serialization.json.*

    import com.greensock.TweenMax;

    import com.greensock.easing.*

    import com.greensock.plugins.*;

    public class FinalConnector extends MovieClip {

        private const _getTokenURL:String = "http://clientloginsolverUrl/youtube.php";

        private var _fileReference:FileReference;

        private var _uploadComplete:Boolean;

        private var _postUrl:String;

        private var _nextUrl:String;

        private var _token:String

        public function FinalConnector() {

            // constructor code

            addEventListener(Event.ADDED_TO_STAGE, configUI);

        }

        private function configUI(e:Event):void {

            stage.scaleMode = StageScaleMode.NO_SCALE;

            stage.align = StageAlign.TOP_LEFT;

            setupBtns();

        }

        private function setupBtns():void{

            login_btn.addEventListener(MouseEvent.CLICK, clickEventHandler);

            upload_btn.addEventListener(MouseEvent.CLICK, clickEventHandler);

            upload_btn.alpha = .1; upload_btn.mouseEnabled = false;

        }

        private function clickEventHandler(e:MouseEvent):void{

            switch(e.currentTarget){

                case login_btn:

                    youTubeLoginGateway();

                break;

                case upload_btn:

                    doUploadClick();

                break;

                /*case logout_btn:

                    doLogoutClick();

                break;*/

            }

        }

        private function youTubeLoginGateway ():void {

            var urlRequest:URLRequest = new URLRequest(_getTokenURL);

            urlRequest.method = URLRequestMethod.GET;

            var urlLoader:URLLoader = new URLLoader();

            urlLoader.addEventListener(Event.COMPLETE, authCompleteHandler);

            urlLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, authFailedHandler);

            urlLoader.addEventListener(IOErrorEvent.IO_ERROR, authFailedHandler);

            urlLoader.load(urlRequest);

        }

        private function authCompleteHandler(event:Event):void {

            var urlLoader:URLLoader = URLLoader(event.target);

            var result:Object = JSON.decode(urlLoader.data);

            _token = result.token;

            _postUrl = result.postUrl;           

            upload_btn.alpha = 1; upload_btn.mouseEnabled = true;

            label_txt.text = urlLoader.data;

        }

        private function authFailedHandler(event:ErrorEvent):void {

            var loginErrorEvent = event;

            ExternalInterface.call("console.log", loginErrorEvent);

        }

        private function doUploadClick():void {

          _fileReference = new FileReference();

          _fileReference.addEventListener(Event.SELECT, fileSelectHandler);

          _fileReference.addEventListener(ProgressEvent.PROGRESS, progressHandler);

          _fileReference.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

          _fileReference.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);

              var videoFilter:FileFilter = new FileFilter("Video", ".*f4v; *.flv; *.wmv; *.mpeg; *.mpg; *.f4v; *.vp8; *.webm; *.3gp; *.mp4; *.mov; *.avi; *.mpegs; *.mpg; *.3gpp;");

            _fileReference.browse([videoFilter]);

        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {

          // Browser-based uploads end with a HTTP 302 redirect to the 'nexturl' page.

          // However, Flash doesn't properly handle this redirect. So we just use the presence of the 302

          // redirect to assume success. It's not ideal. More info on browser-based uploads can be found at

          // http://code.google.com/apis/youtube/2.0/developers_guide_protocol_browser_based_uploading.html

              if (event.status == 302) {

                trace(event);

                _uploadComplete = true;

                label_txt.text = 'File uploaded successfully.';

                TweenMax.to(label_txt, .25, {alpha:1});

              }

        }

        private function fileSelectHandler(event:Event):void {

            _fileReference.addEventListener(Event.COMPLETE, uploadCompleteHandler);

            uploadFile();

        }

        private function uploadCompleteHandler(event:Event):void {

            label_txt.text = "File Uploaded: " + event.target.name;

        }

        private function progressHandler(event:ProgressEvent):void {

              var percent:Number = Math.round(100 * event.bytesLoaded / event.bytesTotal);

            label_txt.text = String(percent);

        }

        private function ioErrorHandler(event:IOErrorEvent):void {

              // uploadComplete is set in the httpStatusHandler when the HTTP 302 is returned by the YouTube API.

              if (!_uploadComplete) {

                trace('An error occurred: ' + event);

              }

        }

        private function uploadFile():void {

            var variables:URLVariables = new URLVariables();

            variables.token = _token;

            variables.nextUrl = "http://whatsoever/success.php";

            label_txt.text = "uploading...";

            TweenMax.to(label_txt, .25, {yoyo:true, repeat:-1, alpha:.5});

            var fileUploadUrl:URLRequest = new URLRequest(_postUrl);

            fileUploadUrl.contentType = "multipart/form-data";

            fileUploadUrl.method = URLRequestMethod.POST;

            fileUploadUrl.data = variables

              _fileReference.upload(fileUploadUrl, 'file');

        }

        //////////// END OF CLASS

    }

}

regards