FlexUnit 4 test cases running sequence problem

Know this thread is old, but in case someone else has this issue in the future., here's how I solved the issue of needing to authenticate. In contrast to the solution outlined in the other thread, mine does not depend on a particular order of the tests. In terms of server load however it's probably heavier, but when testing that shouldn't matter too much. Anyway, in FlexUnit you can create an async startup sequence by defining the async metatag in front of the setUp function. Then, inside the function you call the Async.proceedOnEvent, which will cause the test case to wait with the rest of the tests until the defined event occurs. This way, you can make sure a user has been authenticated before proceeding with tests in the test case and your tests are not depending on a particular order.

[Before(async)]
          public function setUp():void
          {
               _auth = new AuthenticationManager();
               
               // create the mock login event
               var evt:AuthenticationEvent = new AuthenticationEvent(AuthenticationEvent.AUTHENTICATION_EVENT_INITIALIZE, false, false);
               evt.username = "testuser";
               evt.password = "testpassword";
               _auth.authenticate( evt );
               
               Async.proceedOnEvent( this, _auth, AuthenticationEvent.AUTHENTICATION_EVENT_SUCCESS, 5000 );
}

For convenience I created a base class that will handle the authentication for me. Whenever I write a test case that requires authentication I simply subclass my base class and just set the async metatag on the setUp function:

In my test case class:

[Before(async)]
          public function setUp():void
          {
               _service = new Shipments();
               setupAuthentication();
          }

And the base class:

package flexUnitTests
{
     import fi.wegar.events.AuthenticationEvent;
     
     import flowcontrol.models.AuthenticationManager;
     
     import org.flexunit.async.Async;

     public class AuthenticatedTestBase
     {     
          
          protected var _auth:AuthenticationManager;
          
          
          protected function setupAuthentication():void
          {
               _auth = new AuthenticationManager();
               
               // create the mock login event
               var evt:AuthenticationEvent = new AuthenticationEvent(AuthenticationEvent.AUTHENTICATION_EVENT_INITIALIZE, false, false);
               evt.username = "testuser";
               evt.password = "testpassword";
               _auth.authenticate( evt );
               
               Async.proceedOnEvent( this, _auth, AuthenticationEvent.AUTHENTICATION_EVENT_SUCCESS, 5000 );
          }
          
          protected function tearDownAuthentication():void
          {
               _auth = null;
          }
     }
}

The downside to this solution of course is that you're authenticating a user at each call to a test method in the test case, since setUp and tearDown are called for each one of the tests.

Rupam,

By definition unit tests are not supposed to have a dependent order. Doing so means that you are not testing a single 'unit' anymore as there are dependencies.

There are hooks in the code to allow you to do manually sorting on a request, but I doubt most of this works in the beta as it is not a high priority item for us. Eventually, the Order parameter that can be used on test methods will be extended to this level but I don't have a timeline on that.

I am sorry this continues to sound as though our project is incomplete, but you are trying to use it in a way that it was not intended at this point.

If you are feeling very adventerous, I can point you to a place where you could deal with this temporarily. The Suite class (org.flexunit.runners.Suite), which is the one specified in the metadata for your suite finds these classes. You could copy this class, and then specify your own runner using that same metadata and do whatever you would like in there (sort, filter, etc.).

We are going to be pushing some new bits to the SVN site today and releasing another beta soon. If it looks like a low impact change I can try to add this piece in, but I can't guarantee it.

Sorry,

Mike