Textlinemetrics?

The reason why the height is not as you expect is because it is leaving room for a descender. Here's what it looks like with the descender, and the ContainerController's contentBounds outlined in green:

So the extra space at the bottom is space left for the descender.

The extra space at the top in your example isn't duplicated here, probably because you are using Times, and my example is Arial. The first line is placed relative to the top of the container (assuming no paddingTop), such that its baseline will be equal to the font's ascent value. It may be that the Times font has a larger ascent in order to accomodate captial letters with accents; for whatever reason, the ascent of Times is larger than strictly required for the letters you use in your example.

Here's the application I used to generate the image:

package {
   
    import flash.display.Sprite;
    import flash.geom.Rectangle;
   
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.*;
    import flashx.textLayout.formats.TextLayoutFormat;
   
    [SWF(width="450", height="300")]
    public class Bug extends Sprite
    {
       
        public function Bug()
        {
            super();
            init();
        }

        private function init():void
        {      
            var format:TextLayoutFormat = new TextLayoutFormat();
            format.fontSize = "120";
            format.fontFamily = "Times";
           
            var textFlow:TextFlow = new TextFlow();
            textFlow.format = format;
           
            var p:ParagraphElement = new ParagraphElement();
            textFlow.addChild(p);
           
            var span:SpanElement = new SpanElement();
            span.text = "Hello, Worldy";
            p.addChild(span);
           
            textFlow.flowComposer.addController(new ContainerController(this, 400, 300));
            textFlow.flowComposer.updateAllControllers();   
           
           
           
            // "LETS draw the height"
           
            graphics.beginFill(0xff0000);
            graphics.drawRect(0, 0, 10, height);
            graphics.endFill();
           
            graphics.lineStyle(1, 0x00FF00);
            var r:Rectangle = textFlow.flowComposer.getControllerAt(0).getContentBounds();
            graphics.moveTo(r.left, r.top);
            graphics.lineTo(r.right, r.top);
            graphics.lineTo(r.right, r.bottom);
            graphics.lineTo(r.left, r.bottom);
            graphics.lineTo(r.left, r.top);
        }
    }
   
}

- robin