How do I make a scrubber for an animation?

Let me know if you need help with the scrub bar and scrubBar handle.

I did not write this. It will play and scrub the timeline of a movieclip (instance name: MCflow) on the stage.

You will need an MC for the scrub bar (instance name scrubBarMC) and the handle (instance name scrubHandleMC) that users will click and drag. Select both of these MCs, create a new MC and give it an instance name of scrubberMC

Place the button component on the stage and give it an instance name of toggleBtnMC. Add a dynamic text field and give it an instance name frameTxtMC. The text field will display the frame number as the movieclip plays or while you are scrubbing the timeline.

//code for movieclip scrubber

var animLengthMC : int = MCflow.totalFrames;

var leftBoundMC : Number = scrubberMC.scrubBarMC.x;

var rightBoundMC : Number = scrubberMC.scrubBarMC.x + scrubberMC.scrubBarMC.width;

var dragBoundMC : Rectangle = new Rectangle(leftBoundMC, scrubberMC.scrubHandleMC.y, scrubberMC.scrubBarMC.width, 0);

var calcWidthMC : Number = scrubberMC.scrubBarMC.width / animLengthMC;

var animPlayingMC : Boolean = false;

MCflow.gotoAndStop(1);

frameTxtMC.text = String(MCflow.currentFrame);

scrubberMC.scrubHandleMC.x = leftBoundMC;

scrubberMC.scrubHandleMC.buttonMode = true;

scrubberMC.scrubHandleMC.addEventListener(MouseEvent.MOUSE_DOWN, handleMouseEventsMC);

toggleBtnMC.label = "PLAY";

toggleBtnMC.addEventListener(MouseEvent.CLICK, togglePlayMC);

function handleMouseEventsMC(evt:MouseEvent):void

{

  switch(String(evt.type)) {

  case MouseEvent.MOUSE_DOWN:

  scrubberMC.scrubHandleMC.startDrag(false, dragBoundMC);

  stage.addEventListener(MouseEvent.MOUSE_UP, handleMouseEventsMC);

  MCflow.addEventListener(Event.ENTER_FRAME, scrubMovieMC);

  break;

  case MouseEvent.MOUSE_UP:

  scrubberMC.scrubHandleMC.stopDrag();

  stage.removeEventListener(MouseEvent.MOUSE_UP, handleMouseEventsMC);

  MCflow.removeEventListener(Event.ENTER_FRAME, scrubMovieMC);

  break;

  }

}

function scrubMovieMC(evt:Event):void

{

  var scrubPosMC : int = scrubberMC.scrubHandleMC.x;

  var gotoFrameMC : int = Math.ceil(scrubPosMC / calcWidthMC);

  MCflow.gotoAndStop(gotoFrameMC);

  frameTxtMC.text = String(MCflow.currentFrame);

}

function togglePlayMC(evt:MouseEvent):void

{

  if (!animPlayingMC) {

  MCflow.play();

  animPlayingMC = true;

  toggleBtnMC.label = "PAUSE";

  scrubberMC.addEventListener(Event.ENTER_FRAME, updateScrubberMC);

  // DISABLE SCRUBBER INTERACTION WHILE ANIMATION PLAYS

  scrubberMC.mouseChildren = false;

  } else {

  MCflow.stop();

  animPlayingMC = false;

  toggleBtnMC.label = "PLAY";

  scrubberMC.removeEventListener(Event.ENTER_FRAME, updateScrubberMC);

  // ENABLE SCRUBBER INTERACTION AFTER ANIMATION STOPS

  scrubberMC.mouseChildren = true;

  }

}

function updateScrubberMC(evt:Event):void

{

  var percentMC : Number = MCflow.currentFrame / animLengthMC;

  scrubberMC.scrubHandleMC.x = percentMC * scrubberMC.scrubBarMC.width;

  frameTxtMC.text = String(MCflow.currentFrame);

}