idle mode sceensaver time out for android app intrractive

Question

Hi, I'm building an interactive station. with different menus and videos. I have a startup screen that is a movieclip symbol with a video playing. I need help creating a timeout code to return the app to the initial state after 3 minutes of inactivity (no mouse movement or gestures).

will appreciatte any help.

thanks!

JoãoCésar17023019 · Accepted Answer

I'm not sure why.

Animate isn't recognizing my device so I cannot debug the app.

In this case let's go with the setTimeout approach. As an example, I have a very simple app that has two frames: the first one containing a start button and in the second one a timeout of 5 seconds is set and if the user doesn't touch the screen within 5 seconds the timeline returns to frame 1. The code is like this:

Frame 1:

import flash.events.MouseEvent;
import flash.utils.clearTimeout;
import flash.utils.setTimeout;

var delay:uint = 5000;
var timeout:uint = 0;

function main():void
{
	stop();
	startButton.addEventListener(MouseEvent.CLICK, start);
	stage.addEventListener(MouseEvent.MOUSE_DOWN, wake);	
}

function start(e:MouseEvent):void
{
	gotoAndStop(2);
}

function wake(e:MouseEvent):void
{
	clearTimeout(timeout);
	timeout = setTimeout(idle, delay);
}

function idle():void
{
	gotoAndStop(1);
}

main();

Frame 2:

wake(null);

The FLA / source / code / files is in here:

https://github.com/joao-cesar/adobe/tree/master/animate%20cc/as3/idle

I hope it helps.

Regards,

JC

JoãoCésar17023019 · Answer

Hi.

The NativeApplication class has some really useful methods to handle these kind of situations. Have you tried it? You could write something like this:

import flash.desktop.NativeApplication;
import flash.events.Event;

function userIdleHandler(e:Event):void
{
	trace("back");
	// your reset code here
}

NativeApplication.nativeApplication.idleThreshold = 180; // time in seconds
NativeApplication.nativeApplication.addEventListener(Event.USER_IDLE, userIdleHandler);

Please let us know if this works for you.

Regards,

JC

Sign up

To post, reply, or follow discussions, please sign in with your Adobe ID.

Sign in to Adobe Community

To post, reply, or follow discussions, please sign in with your Adobe ID.