36
返信
そうですそうです。
gjiosehさんのコードはAppleScriptなので、新規ドキュメントに全文ペーストして、ウィンドウ左上の選択がAppleScriptになっているのを確認して実行。
（いつの日か）うまく動いた時はそのドキュメントを保存してください。
保存時のファイルフォーマットを「アプリケーション」にすれば、スクリプトエディタで開かなくてもファイルのダブルクリックで実行できるようになります。
ただ現状、gjiosehさんの返信にあるとおり、Photoshopにやらせる部分が未実装なのです。エラーメッセージに出た「 JavaScript コードがありませんでした」そのままの意味ですね。
それは別途用意して組み込む必要があります。
最初に返信したリンク先のコードの、リネーム用の文字列を取得した後の部分（アートボードすべての名前を変更していくところ）は大変参考になると思います。
あとは、AppleScriptが持っている、Numbersから取得した文字列を、どうやってPhotoshopを担当するExtendScriptに渡すか、が解決できればゴールは目前ですね。
検索ワードは「AppleScript do JavaScript 引数」などです。
下記はNumbersで選択したひとつの列からデータを取り出し、Photoshopへ渡すことができるかもしれないAppleScriptです。
ちょっと歯切れが悪いですが、私の環境では現状Photoshopが使えなくて動作確認およびコードの作成ができません。
どなたか作ってくださると.....
下記スクリプトとしては、Numbersでひとつの列にデータを書き込んでおき、その列を選択、実行するとスクリプト内の変数「ii」にリピートでデータが順に一つずつ入ります。
その変数を使ってそれをPhotoshopへ渡し、アートボードが作成できればいけるような気はしてます。
「do javascript "" --Photoshopでの処理をここに」の "" 内にスクリプトを記述すれば、多分いけると思います。多分....
できるとは言い切れてませんのであまり大きな期待は。。。。
use AppleScript version "2.4"
use framework "Foundation"
use scripting additions
tell application "Numbers"
tell front document
tell active sheet
try
set theTable to first table whose class of selection range is range
on error
beep
display alert "何も選択されていません。"
return --何も選択されてなかった場合は終了
end try
tell theTable
set selList to value of (every cell of selection range)
set columnCount to count of (column of selection range) --列をカウント
if columnCount > 1 then
beep
display alert "２列以上選択されています。１列のみ選択してください。"
return
end if
end tell
end tell
end tell
end tell
repeat with i in selList
set ii to contents of i
if ii is not missing value then
log ii
if application id "com.adobe.Photoshop" is running then
tell application id "com.adobe.Photoshop"
if exists front document then
tell front document
try
do javascript "" --Photoshopでの処理をここに
on error msg
return msg
end try
end tell
end if
end tell
end if
end if
end repeat
on regexReplace(aText as text, pattern as text, replacement as text)
--require framework: Foundation
set regularExpression to current application's NSRegularExpression's regularExpressionWithPattern:pattern options:0 |error|:(missing value)
return (regularExpression's stringByReplacingMatchesInString:aText options:0 range:{location:0, |length|:count aText} withTemplate:replacement) as text
end regexReplace
どういたしまして＾＾
最初は誰でもできないところからだと思います。
私も？好きで続いてます。
そのうち面白いものが出来上がるかもしれませんよ。
徐々にでも覚えていってください。
初めは、気になるコードをコピペで動かしてみるといいと思います。
データの羅列を渡す場合、下記はSafariの例ですがPhotoshop(ExtendScript)でも、多分.. 同じような感じで渡せると思います。
-- 配列(リスト)を区切り文字で区切ったテキストに
set |strings| to retDelimedText({"1", "2", "3", "4", "5"}, ",") of me
--> 1,2,3,4,5
tell application "Safari"
if exists front document then --ドキュメントが開かれている場合以下を実行
--変数をテキストとして扱うため変数をシングルクォートで囲み文字列として扱い、.split(',')で分割し配列に
--for文で配列の要素を一つずつ取り出し
do JavaScript "
var array = " & (quoted form of |strings|) & ".split(',');
for (var i = 0;i < array.length; i++) {
alert(array[i]);
}
" in front document
end if
end tell
on retDelimedText(aList, aDelim)
set aText to ""
set curDelim to AppleScript's text item delimiters
set AppleScript's text item delimiters to aDelim
set aText to aList as text
set AppleScript's text item delimiters to curDelim
return aText
end retDelimedText
AdChoices