P: Please make the "Rasterize EPS Format" dialogue box remember the last used settings

I solved the problem using a script written by me.

To solve the problem on the Mac platform I created a droplet app using AppeScript. Each file (or folder) dragged on it will be opened and rasterized in Photoshop (CMYK Mode). Then will be saved in TIFF format in a single layer (flat).
Of course you can modify the script. For example if you prefer to rasterize in RGB mode (and/or) to save a layered tiff.

You can download the script ready to use at the following address:
http://goo.gl/0wU1wK

I am attaching here the source of the script:

(**
==============================
Rasterize eps files (or ai and pdf too)
in Photoshop at 300 DPI to flat tiff
(c) 2014 Carlo Notarianni
Drag and Drop eps (or ai, or pdf) onto droplet
the file(s) will be rasterized
into 300 DPI CMYK Flat TIFF
==============================
**)

on open draggedItems
global itemsConverted
set itemsConverted to 0
repeat with theItem in draggedItems
my ConvertAnyEPSfile(theItem)
end repeat
end open

on ConvertAnyEPSfile(theItem)
tell application "Finder"
local fileType
try
set fileType to file type of theItem
on error
set fileType to "folder"
end try

if fileType is "folder" then
set childItems to (every item of theItem)
repeat with childItem in childItems
my ConvertAnyEPSfile(childItem)
end repeat
else
my convertFile(theItem)
end if
end tell
end ConvertAnyEPSfile

on convertFile(theFile)
local weblocPath, urlPath, theURL, cmd
global itemsConverted

--- Process only eps, .ai and .pdf files
set FilenameExtention to getExtensionName(theFile as text) of me

set ProcessThisFile to false
repeat with validEnd in {"eps", "ai", "pdf"}
if FilenameExtention = (validEnd as text) then
set ProcessThisFile to true
exit repeat
end if
end repeat

(** OK ... the same thing written above can be written in a more simple old way ... but if you have more than 3 extensions ...
if FilenameExtention = "eps" or FilenameExtention = "ai" or FilenameExtention = "pdf" then
set ProcessThisFile to true
end if
**)

set myFilePath to (theFile as text)

if ProcessThisFile then -- Found .eps, or .ai,or .pdf extensions

if FilenameExtention is "eps" then
tell application "Adobe Photoshop CS5"
activate
open file myFilePath as EPS with options {class:EPS open options, mode:CMYK, resolution:300, use antialias:true, constrain proportions:true}
end tell
else
-- In case of .ai or .pdf files...
tell application "Adobe Photoshop CS5"
activate
open file myFilePath as PDF with options {class:PDF open options, mode:CMYK, resolution:300, use antialias:true, constrain proportions:true}
end tell
end if

--
--- The file was rasterized. Now Photoshop can save .tif file
-- First we have to create a "Filename".tif empty container in the same
-- container of the source
-- (the .tif file have to exist before to save...)
set myFilePath to theFile as text
set myFilePathTIF to my getBaseName(myFilePath) & ".tif" --- Change extension's to tif
do shell script "touch " & (quoted form of POSIX path of (myFilePathTIF)) --- Create empty .tif files container

-- OK Finally Photoshop can save and close the .tif file
--The process now is complete for this file. Hurra!
tell application "Adobe Photoshop CS5"
set OutputOptions to {class:TIFF save options, embed color profile:true, image compression:LZW, byte order:IBM PC, save layers:false, save spot colors:true}
save current document in file myFilePathTIF as TIFF with options OutputOptions appending no extension without copying
close current document saving no
end tell
end if
end convertFile

-- Returns the document name without extension (if present)
on getBaseName(fName)
set baseName to fName
repeat with idx from 1 to (length of fName)
if (item idx of fName = ".") then
set baseName to (items 1 thru (idx - 1) of fName) as string
end if
end repeat

return baseName
end getBaseName

-- Returns the document extension's (if present)
on getExtensionName(fName)
set ExtensionName to ""
if fName = "." then return ""
set FileNameLenght to (length of fName)
-- if FileNameLenght < 2 then return ""
repeat with idx from (FileNameLenght) to 1 by -1
if (item idx of fName = ".") and idx ≠ FileNameLenght then
set ExtensionName to (items (idx + 1) thru FileNameLenght) of fName as string
exit repeat
end if
end repeat
if ExtensionName ends with "." then return ""

return ExtensionName
end getExtensionName