When an object with tabEnabled = false is clicked, the default behavior is to remove focus from the currently focused object and set it to null, after raising a MOUSE_FOCUS_CHANGE event.
That event and behavior is supposed to be cancelable, but it does not fire at all and the behavior occurs anyway, when the clicked object already has the focus.
The problem is that when you click an object in flash, tabEnabled is false by default, so a MOUSE_FOCUS_CHANGE event occurs. If you don't cancel the default behavior, the focus is set to null, and a FOCUS_OUT event is raised on the object that used to have the focus, and that event's relatedObject property is null (since the focus is becoming null).
I was trying to override that default behavior in order to prevent FOCUS_OUT events from having null relatedObjects, because for certain objects such as popup menu, I'd like to check whether the object receiving the focus is a child of the popup menu, in which case I would not want to close the menu. Because the default mechanism assigns focus to null when an object with tabEnabled is clicked, I either have to set tabEnabled to true for every conceivable object that might appear as a child in the menu (sorry, not going to happen), or I have to prevent and override the default behavior of MOUSE_FOCUS_CHANGE, and give focus to the object in spite of its tabEnabled property, in order to ensure the relatedObject of the FOCUS_OUT event is not null, so the handler can check whether focus is actually leaving highest level container for the popup menu.
So that's exactly what I did.
But it's not working when the clicked object already has the focus.
In that case, the focus is forcibly removed from the object without any MOUSE_FOCUS_CHANGE event ever firing. As it's easy to see how this was overlooked, because technically the object already having the focus is clicked, so no event is generated. However, it's still following through with the "tabEnabled=false therefore null the focus" behavior, without having raised a mouse focus change event. This is obviously some simple programming error in the Flash Player. If the focus is going to be changed as a result of a mouse click, then the mouse focus change event should fire, giving me the opportunity to cancel it. Alternatively, if the clicked object already has the focus and the player opts not to dispatch a focus change event, then it should not subsequently set the focus to null, as it is currently and illogically doing.
You can see this behavior exhibited by running the following code on a main timeline script; it's fully self-contained:
import flash.events.MouseEvent;
import flash.events.Event;
import flash.events.FocusEvent;
import flash.display.InteractiveObject;
import flash.display.Sprite;
var box:Sprite = new Sprite();
box.graphics.beginFill( 0x000000, 1 );
box.graphics.drawRect( 100, 100, 100, 100 ); //100x100 rectangle offset 100px on each axis
box.graphics.endFill();
box.tabEnabled = false; //focus not assigned by mouse click; we will override this behavior
box.mouseChildren = false; //treat as single region for sake of clicking, do not distinguish clicks on child objects from that of the parent
box.addEventListener( flash.events.MouseEvent.MOUSE_DOWN, mouseDown, false, 0, true );
box.addEventListener( flash.events.FocusEvent.FOCUS_IN, focusIn, false, 0, true );
box.addEventListener( flash.events.FocusEvent.FOCUS_OUT, focusOut, false, 0, true );
addChild( box );
stage.addEventListener( flash.events.FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChange, false, 0, true );
function mouseDown( e:MouseEvent ):void {trace( "mouseDown on " + e.target );}
function focusIn( e:FocusEvent ):void {trace( "focus gained on box, focus used to be " + e.relatedObject );}
function focusOut( e:FocusEvent ):void {trace( "focus lost on box, focus becoming " + e.relatedObject );}
function mouseFocusChange( e:FocusEvent ):void
{
if (e.relatedObject != null) //object receiving the focus
{
trace("mouseFocusChange to " + e.relatedObject + " from " + e.target );
if (!e.relatedObject.tabEnabled)
{
//override default behavior that would set the focus to null, and go ahead and give focus to the clicked object in spite of its tabEnabled value
trace("overriding tabEnabled=false behavior, and assigning focus to clicked object anyway");
e.stopImmediatePropagation();
e.preventDefault();
stage.focus = e.relatedObject;
}
//else proceed with default mouseFocusChange behavior
}
else
trace("mouseFocusChange to nothing from " + e.target );
}
When you run this, click the box one and observe the output. The default behavior is overridden, such that the mouse focus change event is cancelled and focus is assigned to the box in spite of its false tabEnabled value.
Debug output after 1st click:
mouseFocusChange to [object Sprite] from [object Stage]
overriding tabEnabled=false behavior, and assigning focus to clicked object anyway
focus gained on box, focus used to be null
mouseDown on [object Sprite]
When you click the box a second time, I would expect either nothing to occur, since the object already has the focus, OR I would expect the focus change event to fire again, since the player (as you'll see) still plans to set the focus to null because tabEnabled is false. Instead, you'll see that the focus is set to null, but no MOUSE_FOCUS_CHANGE is ever dispatched beforehand to give you the opportunity to cancel the default behavior.
Debug output after 2nd click:
focus lost on box, focus becoming null
mouseDown on [object Sprite]
If you click the box a second time, you'll see that it reverts to the first output since the clicked object does not have the focus anymore. It toggles back and forth each time you click it. Unless I'm missing something, this is a critical flaw in the event system that makes the interception of MOUSE_FOCUS_CHANGE pointless, since the default behavior cannot be intercepted or prevented when the clicked object already has the focus and tabEnabled is false.
1 Correct answer
10
Replies
.
AdChoices