Creating a script to save as a legacy (vers08) .ai

Here you go

-- BEGIN CODE

set fileTypes to {"EPSF", "PDF ", "ART5", "TEXT"} -- file types available to resave as Illustrator

-- get a sourceFolder that holds the files to resave as AI

set sourceFolder to (choose folder with prompt "Choose a folder with files to resave as Illustrator:") as text

-- get a list of files of the defined type in the sourceFolder

tell application "Finder" to set workingFiles to (every file of folder sourceFolder whose file type is in fileTypes) as alias list

-- now you have your fileList argument

-- get a destinationFolder to hold the PDFs

set destinationFolder to choose folder with prompt "Choose a folder to hold the Illustrator files:"

SaveFilesAsIllustrator13(workingFiles, destinationFolder)

on SaveFilesAsIllustrator13(fileList, destinationFolder)

    set destinationPath to destinationFolder as string

    repeat with aFile in fileList

        tell application "Finder"

            set fileName to displayed name of aFile -- get displayed name

            set AppleScript's text item delimiters to "."

            set newFileName to text item 1 of fileName

            set newFilePath to destinationPath & newFileName & ".ai"

        end tell

        tell application "Adobe Illustrator"

            open aFile

            save current document in file newFilePath as Illustrator with options {class:Illustrator save options, compatibility:Illustrator13, embed linked files:true, PDF compatible:true, font subset threshold:0.0}

            close current document saving no

        end tell

    end repeat

end SaveFilesAsIllustrator13

-- END CODE

Ok. Sorry. I'm very new to scripting. I guess I should gave mentioned that.

I was hoping to do it in jscript. I had an action to create the outlines. But you can't use an action to save as a vers 08 ai or eps... Can you ?

Thanks for the replys.

Alex