There doesn't seem to be an easy way to do get an effect's bounds. I thought about checking if any of the selected items has an effect and calculate the offset via the effect's settings properties—the drop shadow settings has distance, offset, and angle. Too much work.
Before running the script you could include an empty frame to define the effect's bounds.
There is also a problem with the first script where the default margins might be a problem for small selections. I think this is a fix:
(* Rob Day 2015-2018
Exports a PDF from a selection of page items *)
tell application "Adobe InDesign CC 2018"
activate
-------------------------------Selection check----------------------------------
if (count documents) is equal to 0 then
display dialog "Please open a document" buttons " OK " default button 1 with icon caution
return -128
end if
if saved of active document is false then
display dialog "Please save your document document" buttons " OK " default button 1 with icon caution
return -128
end if
try
my getSelBounds(selection)
on error
return
end try
-------------------------------Dialog----------------------------------
--PDF preset choice.
set myLabelWidth to 250
set myDialog to make dialog with properties {name:"Export Selection as PDF"}
tell myDialog
tell (make dialog column)
tell (make border panel)
tell (make dialog column)
tell (make dialog row)
set PresertList to name of every PDF export preset of application "Adobe InDesign CC 2018"
make static text with properties {static label:"PDF Preset:"}
set myPDFPresetDropdown to make dropdown with properties {string list:PresertList, selected index:3, min width:myLabelWidth}
end tell
--Crops Checkbox
tell (make dialog row)
set myCropsCB to make checkbox control with properties {static label:"Include Marks", checked state:true, min width:myLabelWidth}
end tell
--Open PDF
tell (make dialog row)
set myOpenCB to make checkbox control with properties {static label:"Open Selection PDF", checked state:true, min width:myLabelWidth}
end tell
end tell
end tell
end tell
end tell
--get the results
set myResult to show myDialog
if myResult = true then
--+1 gets the correct name because list starts at 0
set myPDFPreset to item ((selected index of myPDFPresetDropdown) + 1) of PresertList as item
set usemarks to checked state of myCropsCB
set openPDF to checked state of myOpenCB
else
return
end if
destroy myDialog
end tell
-------------------------------Set & Save Preferences----------------------------------
tell application "Adobe InDesign CC 2018"
try
set d to active document
--save application and doc view prefs
set appviewprefs to properties of view preferences
set docviewprefs to properties of view preferences of d
--save the default document preset properties
set defpre to item 1 of every document preset whose name is "[Default]"
set defprop to properties of item 1 of defpre
--use spread in case selection crosses the spine
set properties of view preferences of d to {ruler origin:spread origin}
--set the path for the selection PDF to the same folder as the ID file
set pth to file path of d
set nme to name of d
set nme to characters 1 thru -6 of nme as string
set thePath to pth & nme & "-selection.pdf" as string
--gets the selection bounds
set {aa, bb, cc, dd} to my getSelBounds(selection)
copy
-------------------------------Make Selection Document----------------------------------
--document setup (height, width, margin-top, margin-right, margin-bottom, margin-left, bleed, columns, facing?, num pages)
my docSetup(cc - aa, dd - bb, 0, 0, 0, 0, 0, 1, false, 1)
--make the selection doc.
set exportdoc to make new document with properties {document preset:"[Default]", CMYK policy:CMYK policy of d, RGB policy:RGB policy of d, after blending intent:after blending intent of d, solid color intent:solid color intent of d, RGB profile:RGB profile of d, accurate LAB spots:accurate LAB spots of d, view preferences:properties of view preferences of d, zero point:{0.0, 0.0}}
-------------------------------Export----------------------------------
tell exportdoc
--adjust page width & height for the selection (for some reason doc setup width and height doesn't always work)
set page width of document preferences to dd - bb
set page height of document preferences to cc - aa
tell application "Adobe InDesign CC 2018"
paste
end tell
my exportPDF(exportdoc, thePath, myPDFPreset, usemarks)
close saving no
end tell
------------------------------- Reset Prefs ----------------------------------
set properties of view preferences of d to docviewprefs
set properties of view preferences to appviewprefs
set properties of item 1 of defpre to defprop
--open PDF
tell application "Finder"
if openPDF then
open file thePath
end if
end tell
on error
--reset if there is an error
set properties of view preferences of d to docviewprefs
set properties of view preferences to appviewprefs
set properties of item 1 of defpre to defprop
end try
end tell
------------------------------- functions ----------------------------------
--get multi selection bounds
on getSelBounds(s)
tell application "Adobe InDesign CC 2018"
try
set {e, f, g, h} to visible bounds of item 1 of s
on error
display dialog "Please select a page item"
end try
repeat with x in s
set {a, b, c, d} to visible bounds of x
if a is less than e then
set e to a
end if
if b is less than f then
set f to b
end if
if c is greater than g then
set g to c
end if
if d is greater than h then
set h to d
end if
end repeat
end tell
return {e, f, g, h}
end getSelBounds
--export (doc, savepath, preset, usemarks?)
on exportPDF(d, p, prst, m)
tell application "Adobe InDesign CC 2018"
set pset to properties of PDF export preset prst
set properties of PDF export preferences to pset
set properties of PDF export preferences to {page range:all pages, use document bleed with PDF:false, bleed marks:false, crop marks:m, view PDF:false, registration marks:false}
export d format PDF type to p
end tell
end exportPDF
--set the default preset for new doc (height, width, margin-top, margin-right, margin-bottom, margin-left, bleed, columns, facing?, num pages)
on docSetup(h, w, mt, mr, mb, ml, b, c, fp, tp)
tell application "Adobe InDesign CC 2018"
set properties of item 1 of every document preset whose name is "[Default]" to {document bleed bottom offset:b, document bleed uniform size:true, column count:c, bottom:mb, left:ml, right:mr, top:mt, pages per document:tp, page height:h, facing pages:fp, page width:w, start page number:1}
end tell
end docSetup
25
Replies
AdChoices