You are welcome to try this for what its worth. It should do 2 things. First if there is a Photoshop "warning" record the info the dismiss the dialog proceed with file else record the "error" info kicked back to AppleScript but not process this file. This is a far as I got with this and you would be well advised to do some testing of your own. Requires Enable access for assistive devices this is in system prefs.
property Error_Report : (path to desktop folder as Unicode text) & "Problem Image Report.txt"
global PS_Info
set PS_Info to ""
--
set The_File to choose file
--
tell application "Adobe Photoshop CS2"
activate
try
with timeout of 2 seconds
open The_File
end timeout
on error
my Check_For_Dialogs()
tell application "System Events"
tell application process "Adobe Photoshop CS2"
keystroke return
end tell
my Problem_Images(The_File, PS_Info)
end tell
end try
if exists document 1 then
set Doc_Ref to the current document
tell Doc_Ref
-- do your stuff here
end tell
end if
end tell
--
on Check_For_Dialogs()
-- This should catch the text of a Photoshop warning dialog
try
tell application "System Events"
if UI elements enabled then
tell window 1 of application process "Adobe Photoshop CS2"
if title contains "Adobe Photoshop" then set PS_Info to value of static text 2
end tell
else
tell application "System Preferences"
activate
set current pane to pane "com.apple.preference.universalaccess"
display dialog "UI element scripting is not enabled. Check \"Enable access for assistive devices\""
end tell
end if
end tell
return PS_Info
-- This should catch an error kicked back to AppleScript
on error eM number eN
set PS_Info to "Error: " & eN & ". " & eM
return PS_Info
end try
end Check_For_Dialogs
--
on Problem_Images(The_File, PS_Info)
-- Whatever info about the file you want a record of…
set File_Name to name of (info for The_File)
-- String of records to write to "Problem Image Report" text file…
set The_Info to File_Name & tab & PS_Info & return
try
open for access file the Error_Report with write permission
write The_Info to file the Error_Report starting at eof
close access file the Error_Report
on error
close access file the Error_Report
end try
end Problem_Images
Writes out a report at desktop with info like:
11234567890 copy 3.tif Error: -2763. Cannot open the file because the open options are incorrect
hfgfhr.jpg This document may be damaged (the file may be truncated or incomplete). Continue?
22
Replies
AdChoices