File.copyTo (and copyToAsync) extremely slow on Android. e.g. 1/2 second per tiny XML file. Help?

Hi all,

I ran into the same problem on Android: File.copyToAsynch is terribly slow. For 200 files of about 42mb total, it took my Samsung Note 10.1  85 secs to copy from app dir to storage dir! (I have to copy the files to storage dir to be able to read modification date, which is not present in app dir, for an update scheme.)

The solution I ended up with is very simple:

Iterate recursively over folder that you want to copy.

For each file that is not a directory, open the file (using FileStream) , read the bytes, write the bytes to a file on the target directory and close the streams.

This took only 5 secs for the same 200 files / 42 mbs. As this happens only on first run of my app, this is very acceptable.

Here is my code :

------------------------------------------

var folder:String = "content/";//supply your folder here

var src:File = File.applicationDirectory.resolvePath(folder);

var goal:File = File.applicationStorageDirectory;

var bytes:ByteArray = new ByteArray();

var stream:FileStream = new FileStream();

var iterate:Function = function(dir:File, path:String):void

{

                                        var files:Array = dir.getDirectoryListing();

                                        for each(var file:File in files)

                                        {

                                                  if (file.isDirectory)

                                                  {

                                                            iterate(file, path + file.name + File.separator);

                                                  }

                                                  else

                                                  {

                                                            bytes.clear();

                                                            stream.open(file, FileMode.READ);

                                                            stream.readBytes(bytes);

                                                            stream.close();

                                                            var dest:File = goal.resolvePath(path+file.name);

                                                            stream.open(dest, FileMode.WRITE);

                                                            stream.writeBytes(bytes);

                                                            stream.close();

                                                  }

                                        }

}

iterate(src, folder);

------------------------------------------

This could easily be reworked to work asynch of course.

Hope this works for other people as well.

Reinier