Applescript InDesign 2025 export JPG no longer works

Question

Hello everyone.

I created a script 2 years ago with INDD 2022 (I think).
When I try this script with INDD 2025 and MacOS Sequoia, it no longer works.
Basically, it creates QR codes from urls in an XLS file and export each QR codes as a JPG with a specific name.
There are more than 400 JPGs to do.

I've reduced the script as much as possible to find the error... and I don't understand.
JPG export doesn't work (I don't have a JPG file) without any error;
PDF export produces an error: Error in Adobe InDesign 2025: Unable to export PDF file (something like this… this is a translation of my french version)

Any idea?

Thanks a lot

tell application "Finder"

set myJPGfolder to "Macintosh HD:Users:olivier:Desktop:JPGs:" as alias

end tell

tell application "Adobe InDesign 2025"

activate

tell active document

set myRectangle to make new rectangle with properties {geometric bounds:{5, 5, 25, 25}}

set QRCodeURL to "https://www.apple.com"

set JPG_Name to "945_0"

Create Hyperlink QR Code myRectangle url link QRCodeURL

set myJpgFilePath to (myJPGfolder & JPG_Name & ".jpg") as string

set myPDFFilePath to (myJPGfolder & JPG_Name & ".pdf") as string

export to myJpgFilePath format JPG

export to myPDFFilePath format PDF type

end tell

m1b · Accepted Answer

Hi @Olivier-Coolgray, here's a little script that might help.

- Mark

tell application "Adobe InDesign 2025"
	
	set exportPath to "/Users/mark/Desktop/JPGs/page.jpg"
	
	-- Check if a document is open
	if (count of documents) is 0 then
		display dialog "No document is open!" buttons {"OK"} default button "OK"
		return
	end if
	
	set doc to document 1
	set pageNum to 1 -- Change this to export a different page
	
	tell JPEG export preferences
		set anti alias to true
		set Page String to pageNum as string
		set Exporting Spread to false
		set JPEG export range to export range
		set JPEG Quality to maximum
		set export resolution to 300
		set use document bleeds to false
	end tell
	
	tell doc
		-- Export the page as a JPG
		export to exportPath format JPG without showing options
	end tell
	
	display dialog "Export complete!" buttons {"OK"} default button "OK"
	
end tell

Olivier-Coolgray · Answer

I found this and it seems to worktell application "Finder"set myFolder to POSIX path of ("/Users/olivier/Desktop/JPGs/")end tell

Sign up

To post, reply, or follow discussions, please sign in with your Adobe ID.

Sign in to Adobe Community

To post, reply, or follow discussions, please sign in with your Adobe ID.

Scanning file for viruses.

This file cannot be downloaded