Inherited Indesign file images

Hi @designthis86 , Try this AppleScript—it converts pasted images into links:

https://shared-assets.adobe.com/link/76c4e50a-97fd-4fcf-7bba-6638f982846a

Here’s the code:

(* 
Rob Day 2012-2018 
extracts pasted or embedded images and vectors from an ID layout as PDF and links to the PDF.
The PDF link has complete res and color info
*)

tell application "Adobe InDesign 2021"
	--make sure the clipboard pref is copy PDF
	set MyClipPref to copy PDF to clipboard of clipboard preferences
	set copy PDF to clipboard of clipboard preferences to true
	
	--where to copy embedded files
	set myFolder to (choose folder with prompt "Please select the folder you want to save your PDF pages in") as string
	set myDocument to active document
	
	--get all of the doc's page items
	set pitems to all page items of every page item of myDocument
	
	--empty path and image name lists for linking later
	set imagePaths to {}
	set copiedimages to {}
	
	repeat with i from 1 to number of items in pitems
		
		-- a placed item is item 1 of the page item, try skips everything else
		try
			set myPic to item 1 of item i of pitems
			
			--the placed file's item link, pasted files return nothing
			set x to item link of myPic
			
			--check for pasted or embedded files, 
			if x is nothing or status of x is link embedded then
				
				--select the placed for copying
				select myPic
				
				--the the link id to use as a name
				set myname to id of myPic
				
				--the scale
				set hs to horizontal scale of myPic
				set vs to vertical scale of myPic
				
				--temporarily set the scale to 100% so the copy is the original actual resolution
				set horizontal scale of myPic to 100
				set vertical scale of myPic to 100
				
				--copy and reset the scale
				copy
				set horizontal scale of myPic to hs
				set vertical scale of myPic to vs
				
				--save the clipboard as a PDF
				tell application "Finder"
					my saveImage(myFolder, myname)
				end tell
				
				--save the paths and images as lists for linking
				set end of imagePaths to myFolder & myname & ".pdf"
				set end of copiedimages to myPic
			end if
		end try
	end repeat
	
	--link the saved files
	repeat with j from 1 to number of items in imagePaths
		set itemlink to item j of imagePaths
		place alias itemlink on item j of copiedimages
	end repeat
	
	--reset preference
	set copy PDF to clipboard of clipboard preferences to MyClipPref
end tell

-------------------------------Functions----------------------------------

--writes clipboard to disk
--save folder, image name
on saveImage(theFolder, filename)
	--the save path
	set myPath to theFolder & filename & ".pdf"
	try
		set myFile to (open for access myPath with write permission)
		set eof myFile to 0
		write (the clipboard as «class PDF ») to myFile -- as whatever
		close access myFile
		return (POSIX path of myPath)
	on error
		try
			close access myFile
		end try
		return ""
	end try
end saveImage