1 Correct answer
Here is the complete code for reference:
...import flash.events.MouseEvent;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundTransform;
import flash.net.URLRequest;
import flash.display.SimpleButton;
import flash.events.Event;
var bgmList:Vector.<String> = new <String>
[
"https://website.com/Beat_Your_Competition.mp3",
"bgm/Bounce_House.mp3",
"bgm/Chess_Pieces.mp3"
];
var sound:Sound;
var sChannel:SoundChannel;
var sTransform:SoundTransform;
var channelPosition:Number
27
Replies
Hi.
Did this small sample for you.
Notice that it has only three buttons. But you can add as many as you want. Just don't forget to rename them accordingly and to set the song path for each.
Code:
import flash.events.MouseEvent;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundTransform;
import flash.net.URLRequest;
import flash.display.SimpleButton;
import flash.events.Event;
var folder:String = "bgm";
var bgmList:Vector.<String> = new <String>
[
folder + "/" + "Beat_Your_Competition.mp3",
folder + "/" + "Bounce_House.mp3",
folder + "/" + "Chess_Pieces.mp3"
];
var sound:Sound;
var sChannel:SoundChannel;
var sTransform:SoundTransform;
var channelPosition:Number = 0;
var playing:Boolean = false;
var paused:Boolean = false;
var currentSound:int = -1;
function onMouse(e:MouseEvent):void
{
if (e.type == MouseEvent.CLICK)
{
if (e.currentTarget.parent == soundButtons)
changeSound(e.currentTarget as SimpleButton);
else if (e.currentTarget.parent == controlButtons)
{
if (e.currentTarget == controlButtons.pauseButton)
pauseSound();
else if (e.currentTarget == controlButtons.playButton)
playSound(channelPosition);
else if (e.currentTarget == controlButtons.stopButton)
stopSound();
}
controlStates();
}
}
function changeSound(button:SimpleButton):void
{
currentSound = int(button.name.slice(5, button.name.length));
channelPosition = 0;
nowPlaying.text = "Current song = " + bgmList[currentSound].replace("bgm/", "");
if (playing)
{
sChannel.stop();
playSound(channelPosition);
}
}
function pauseSound():void
{
if (playing)
{
channelPosition = sChannel.position;
sChannel.stop();
playing = false;
paused = true;
}
}
function playSound(start:Number = 0, volume:Number = 1, loops:int = 0):void
{
if (currentSound == -1)
return;
if (sChannel)
sChannel.stop();
sound = new Sound();
sTransform = new SoundTransform();
sound.load(new URLRequest(bgmList[currentSound]));
sChannel = sound.play(start, loops);
sTransform.volume = volume;
sChannel.soundTransform = sTransform;
playing = true;
paused = false;
}
function stopSound():void
{
if (sChannel)
{
sChannel.stop();
channelPosition = 0;
playing = false;
paused = false;
}
}
function controlStates():void
{
if (playing)
{
progress.visible = true;
bar.visible = true;
controlButtons.pauseButton.alpha = 1;
controlButtons.stopButton.alpha = 1;
}
else
{
controlButtons.pauseButton.alpha = 0.35;
if (!paused)
{
progress.visible = false;
bar.visible = false;
controlButtons.stopButton.alpha = 0.35;
}
}
}
function enterFrameHandler(e:Event):void
{
if (playing)
{
if (sound.length > 0)
progress.scaleX = sChannel.position / sound.length;
}
}
function start():void
{
stop();
for (var i:int = 0, total:int = soundButtons.numChildren; i < total; i++)
soundButtons.getChildAt(i).addEventListener(MouseEvent.CLICK, onMouse);
for (i = 0, total = controlButtons.numChildren; i < total; i++)
controlButtons.getChildAt(i).addEventListener(MouseEvent.CLICK, onMouse);
stage.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
nowPlaying.text = "Current song = none."
controlStates();
}
start();
FLA download: animate_cc_as3_play_sounds.zip - Google Drive .
Preview:
Regards,
JC
Nice!
Remove the folder variable and update the bgmList and the changeSound function like this:
var bgmList:Vector.<String> = new <String>
[
"https://website.com/Beat_Your_Competition.mp3",
"bgm/Bounce_House.mp3",
"bgm/Chess_Pieces.mp3"
];
function changeSound(button:SimpleButton):void
{
currentSound = int(button.name.slice(5, button.name.length));
channelPosition = 0;
nowPlaying.text = "Current song = " + bgmList[currentSound].split("/").pop();
if (playing)
{
sChannel.stop();
playSound(channelPosition);
}
}
Sorry because I completely forgot to consider online files. 
This is just wonderful!
Thank you so much! 
I have now two more questions. Iwould like sound to be played if I choose a Soundbutton, instead of choosing the channel and then pushing play. Would that be possible?
Again, thank you so much!
I changed the code a little to match with my working code.
So what I did is this:
var container:MovieClip = new MovieClip;
addChild(container);
for (var i:int = 0, total:int = xmlLengde; i < total; i++){
bgmList.push(myXML..Song.songURL)
button = new SongButton();
button.y = mcTopic.height+blaatt.height + button.height*i + i*5;
button.txt.autoSize = TextFieldAutoSize.LEFT;
button.txt.text = myXML..Song.songTitle;
button.width=stage.stageWidth* (9/10);
button.x = (stage.stageWidth-button.width)/2;
var countryID=myXML..Song.countryID;
trace("countryID: " + countryID)
var myMovieClip=images[countryID];
var bitmapData:BitmapData = new BitmapData(myMovieClip.width, myMovieClip.height);
bitmapData.draw(myMovieClip);
var bitmap:Bitmap = new Bitmap(bitmapData);
bitmap.y=(button.height-bitmap.height)/2;
bitmap.x=10;
button.txt.x=bitmap.x+bitmap.width+5;
button.addChild(bitmap);
container.addChild(button);
}
So when I click my controlButtons - which I is not coded. But added 3 buttons inside a movieclip, stop - play - pause.
I trace "clicketyclack",
But when I click the buttons, nothing happens. Which is wierd. Looks like the buttons I have added works as graphics and not buttons. Since when I "hover"/hold the mouse over the buttons, the hands doesnt show, unless I hold it over control buttons.
If that was understandable? 
Do you know why? here is the function which traces for a click.
+
I added all the buttons into "container",
function onMouse(e:MouseEvent):void
{
trace("clicketyclack");
if (e.type == MouseEvent.CLICK)
{
if (e.currentTarget.parent == soundButtons)
changeSound(e.currentTarget as SimpleButton);
else if (e.currentTarget.parent == controlButtons)
{
if (e.currentTarget == controlButtons.pauseButton)
pauseSound();
else if (e.currentTarget == controlButtons.playButton)
playSound(channelPosition);
else if (e.currentTarget == controlButtons.stopButton)
stopSound();
}
controlStates();
}
}
Thank you. I tried changing the e.CurrentTarget to e.target, same result. The controlbuttons seem to work.
I do not think the issue lays in the function onMouse.
This is what I think the issue might be:
So the Radio Swiss Classic and Lounge FM Accoustic are buttons* I created using the script. I added them as children under a MovieClip. When I "hoover" my mouse over them, the mouse does not turn into a hand.
While on the other hand. The ControlButtons shows hands when hoovering them, the same does my old working application where I have created the buttons with logos and added them inside a movieclip.
What I am thinking is happening is that since the SoundButton is a MovieClip, and I dont tell it to be a button anywhere. Thats where the issue is.
var button:SongButton;
button = new SongButton();
So what I just tried is changing the "SongButton" from MovieClip to a Button, but then I get issues with the txt inside the SongButton. I get issues with button.addChild(bitmap);
Maybe just before this code: container.addChild(button);
I should tell the "button" to become a Button? somehow
Thank you for taking the time over and over 
https://www.dropbox.com/sh/w2jiio8j8c9tove/AABXOlSkzHcuSdLrcIqUK_rMa?dl=0
Here you go
I think I used the file you shared with me earlier about the SoundButton. Which has this code:
package {
import flash.display.MovieClip;
public class SongButton extends MovieClip {
public function SongButton() {
// constructor code
}
}
}
Thanks
AdChoices