trying to understand classes having a hard time

Hi.

When you declare a variable or function inside of a class block, you're adding a property or method to an instance of that class. For example:

[Person.as]

package
{
     public class Person
     {
          private var _firstName:String = "";
          private var _lastName:String = "";
          public function Person()
          {
          }
          public function getFirstName():String
          {
               return _firstName;
          }
          public function setFirstName(name:String):void
          {
               _firstName = name;
          }
          public function getLastName():String
          {
               return _lastName;
          }
          public function setLastName(name:String):void
          {
               _lastName = name;
          }
          public function getFullName():String
          {
               return _firstName + " " + _lastName;
          }
     }
}

[FLA code]

var person1:Person = new Person();
person1.setFirstName("Nathan");
person1.setLastName("Drake");
trace(person1.getFirstName());
trace(person1.getLastName());
trace(person1.getFullName());
var person2:Person = new Person();
person2.setFirstName("Lara");
person2.setLastName("Croft");
trace(person2.getFirstName());
trace(person2.getLastName());
trace(person2.getFullName());

So you have to instanciate a class before using its methods and properties.

But if you want methods and properties that belong to the class itself and not to a specific instance, you have to use the static keyword.

[Person.as]

package
{
     public class Person
     {
          private var _firstName:String = "";
          private var _lastName:String = "";
          private static var _peopleCount:uint = 0; // NEW
          public function Person()
          {
               _peopleCount++; // NEW
          }
          public function getFirstName():String
          {
               return _firstName;
          }
          public function setFirstName(name:String):void
          {
               _firstName = name;
          }
          public function getLastName():String
          {
               return _lastName;
          }
          public function setLastName(name:String):void
          {
               _lastName = name;
          }
          public function getFullName():String
          {
               return _firstName + " " + _lastName;
          }
          
          // NEW
          public static function numberOfPeople():uint
          {
               return _peopleCount;
          }
     }
}

[FLA code]

var person1:Person = new Person();
person1.setFirstName("Nathan");
person1.setLastName("Drake");
trace(person1.getFirstName());
trace(person1.getLastName());
trace(person1.getFullName());
trace(Person.numberOfPeople()); // NEW
var person2:Person = new Person();
person2.setFirstName("Lara");
person2.setLastName("Croft");
trace(person2.getFirstName());
trace(person2.getLastName());
trace(person2.getFullName());
trace(Person.numberOfPeople()); // NEW

Now, with this new static function numberOfPeople, I can keep track of how many people have been created. It makes sense to set this method as static because the number of instances is an information that regards to the whole class not to a specific instance.

For comparison, take the default Math class and its methods: Math.random, Math.abs, and so on. You don't need to instanciate the Math class to use them. Because they are static.

About importing, it's not mandatory by default to import classes in the same folder. But for classes in subfolders, you have to use an import statement. Just remember to set your code respositories in the AS3 settings.

In AS3, objects can only extend one class. You can add multiple interfaces, though.

And there is a debate if OOP is the best approach or not. What I like to do is to use a mix of procedural and OOP approaches for simple situations and a more involved OOP implementation for larger and more complex projects.

If you want a very deep and detailed explanation about OOP and other AS3 stuff, please have a look at this series by Dru Kepple:

https://code.tutsplus.com/series/as3-101--active-7395

I hope this helps.

Regards,

JC