CFMAIL Attached vs. embedded (cfmail, multipart/mixed)

I never found a solution using cfmail.  I had to resort to java instead.

I have all of my file information (including content) in a query called qFiles and loop through that in the code below.

<cfscript>

    // config will stay this way

    emailServer = serverAddressHere;

    emailServerAccount = "";

    emailServerPwd = "";

    //  set email variables

    vSentFrom = sentFromEmailHere;

    vSubjectText = subjectHere;

    recipientsTo = listToArray( SentToListHere );

    recipientsCC = listToArray( CCListHere );

    recipientsBCC = listToArray( BCCListHere );

    // set javamail properties

    props = createObject("java", "java.util.Properties").init();

    props.put("javax.mail.smtp.host", emailServer);

    // get static recipient types

    recipientType = createObject("java", "javax.mail.Message$RecipientType");

    // create the session for the smtp server

    mailSession = createObject("java", "javax.mail.Session").getInstance(props);

    // create a new MIME message

    mimeMsg = createObject("java", "javax.mail.internet.MimeMessage").init(mailSession);

    // create the to and from e-mail addresses

    addrFrom = createObject("java", "javax.mail.internet.InternetAddress").init(vSentFrom);

    for (cfIdx = 1; cfIdx LTE arrayLen( recipientsTo ); cfIdx++)

    {   

        addrTo[cfIdx] = createObject("Java", "javax.mail.internet.InternetAddress").init( recipientsTo[cfIdx] );

        // add a recipient

        mimeMsg.addRecipient(recipientType.TO, addrTo[cfIdx]);

    }

    if(ArrayLen(recipientsCC)){

        for (cfIdx = 1; cfIdx LTE arrayLen( recipientsCC ); cfIdx++)

        {

            addrCC[cfIdx] = createObject("Java", "javax.mail.internet.InternetAddress").init( recipientsCC[cfIdx] );

            // add a recipient

            mimeMsg.addRecipient(recipientType.CC, addrCC[cfIdx]);

        }

    }

    if(ArrayLen(recipientsBCC)){

        for (cfIdx = 1; cfIdx LTE arrayLen( recipientsBCC ); cfIdx++)

        {

            addrBCC[cfIdx] = createObject("Java", "javax.mail.internet.InternetAddress").init( recipientsBCC[cfIdx] );

            // add a recipient

            mimeMsg.addRecipient(recipientType.BCC, addrBCC[cfIdx]);

        }

    }

    // build message

    // set who the message is from

    mimeMsg.setFrom(addrFrom);

    // set the subject of the message

    mimeMsg.setSubject(vSubjectText);

    // create multipart message: only needed if you're including both plain/text and html

    // or using attachments

    multipart = createObject("java", "javax.mail.internet.MimeMultipart").init();

    // specifies that the message contains both inline text and html, this is so that

    // images given a cid will show up when rendered by the e-mail client

    multipart.setSubType("mixed");

    // create html text multipart

    oHtml = createObject("java", "javax.mail.internet.MimeBodyPart").init();

    // add the html content (the setText() method shortcut/only works for "plain/text")

    oHtml.setContent( emailContentHTML, "text/html");

    // add the body part to the message

    multipart.addBodyPart(oHtml);

    // loop over files to attach to the email

    for ( intRow = 1 ; intRow LTE qFiles.RecordCount ; intRow = (intRow + 1))

    {

    // set file info to vars

    fileContent = qFiles["fileContent"][intRow];

    fileMimeType = qFiles["mimeType"][intRow];

    fileName = rereplace( qFiles["filename"][intRow] , '(?!\.[^.]*$)\W' , '' , 'all' );

    if(len(fileName) > 50)

    {fileName = mid(fileName,1,44) & right(fileName,find('.',reverse(fileName)));}

    // attach an inline binary object

    att = createObject("java", "javax.mail.internet.MimeBodyPart").init();

    // create an octet stream out of the binary file

    os = createObject("java", "org.apache.axis.attachments.OctetStream").init(fileContent);

    // we now convert the octet stream into the required data source. using an octet stream

    // allows us pass in any binary data as a file attachment

    osds = createObject("java", "org.apache.axis.attachments.OctetStreamDataSource").init("", os);

    // initialize the data handler using the data source

    dh = createObject("java", "javax.activation.DataHandler").init(osds);

    // pass in the binary object to the message--javamail will handle the encoding

    // based on the headers

    att.setDataHandler(dh);

    // define this binary object as a PDF

    att.setHeader("Content-Type", fileMimeType);

    // make sure the binary data gets converted to base64 for delivery

    att.setHeader("Content-Transfer-Encoding", "base64");

    // specify the binary object as an attachment

    att.setHeader("Content-Disposition", "attachment");

    // define the name of the file--this is what the filename will be in the e-mail client

    att.setFileName(fileName);

    // add the body part to the message

    multipart.addBodyPart(att);

    }

    //end loop through qFiles

    // place all the multi-part sections into the body of the message

    mimeMsg.setContent(multipart);

    // in this section we'll build the message into a string. you could dump

    // the string to a file in most SMTP server's queue file for delivery

    // this is exactly what would be pass to the SMTP server

    // create a bytearray for output

    outStream = createObject("java", "java.io.ByteArrayOutputStream");

    // create a budder for the output stream

    outStream.write(repeatString(" ", 1024).getBytes());

    // save the contents of the message to the output stream

    mimeMsg.writeTo(outStream);

    // save the contents of the message to the sMailMsg variable

    sMailMsg = outStream.toString();

    // reset the output stream (for stability)

    outStream.reset();

    // close the output stream

    outStream.close();

    // create a transport to actually send the message via SMTP

    transport = mailSession.getTransport("smtp");

    // connect to the SMTP server using the parameters supplied; use

    // a blank username and password if authentication is not needed

    transport.connect(emailServer, emailServerAccount, emailServerPwd);

    // send the message to all recipients

    transport.sendMessage(mimeMsg, mimeMsg.getAllRecipients());

    // close the transport

    transport.close();

    </cfscript>