Where is the Coldfusion forum?

As WolfShade says, cftable has been deprecated. Nevertheless, I can think of a very easy way to implement what you want. The demo is as follows.

1) Create the following database table, with columns cityID(varchar 10), custID(varchar 10) and custName(varchar 30). Call it customer:

2) Store the following 3 files within the same directory under the web root:

cities.cfm

<!--- Code at top of page --->

<cfif isdefined("form.city")>

    <cfset cityCustomerObject = createobject("component","CityCustomer")>

    <cfset customerQuery = cityCustomerObject.getCustomers(form.city)>

</cfif>

<cfoutput><form action="#cgi.script_name#" method="post"></cfoutput>

<select name="city" id="city" onchange="this.form.submit()">

    <option value="">Select city</option>

    <option value="ct1">city 1</option>

    <option value="ct2">city 2</option>

    <option value="ct3">city 3</option>

</select>

</form>

<!--- Code at bottom of page --->

<form action="actionPage.cfm" method="post">

<select name="customer" id="customer">

    <option value="">Select customer</option>

    <cfif isdefined("form.city")>

        <cfoutput query="customerQuery">

             <option value="#custID#">#custname#</option>

        </cfoutput>

    </cfif>  

</select><br>

<input type="submit" name="sbmt" value="Send">

</form>

CityCustomer.cfc

<cfcomponent>

    <cffunction name="getCustomers" returntype="query">

        <cfargument name="cityID" >

        <cfset var customers = queryNew("")>

         <!--- dsn = name of datasource in which customer table stored. dsn should be registered in the administrator--->

        <cfquery name="customers" datasource="dsn">

            select custID, custName

            from customer

            where cityID = <cfqueryparam cfsqltype="cf_sql_varchar" value="#arguments.cityID#">

        </cfquery>

        <cfreturn customers>

    </cffunction>

</cfcomponent>

actionPage.cfm

Selected customer ID: <cfif isdefined("form.customer")><cfoutput>#form.customer#</cfoutput></cfif>

Get the ball rolling by opening the page cities.cfm in the browser. The rest follows from there.