Document Size from Image

This AppleScript (OSX only) seems to to work. It uses OSX's command line to get the chosen image's dimensions and makes a new ID doc to match. This would be harder with JavaScript, but might be possible by getting the image dimensions from Photoshop using BridgeTalk.

(*
Rob Day 2018
--Gets a chosen image's dimensions and makes a new ID doc with matching dimensions then places
*)
tell application "Adobe InDesign CC 2018"
   
    -------------------Get chosen file's width and height-----------------------
    try
        set f to (choose file with prompt "Select Image")
        set w to my getImage(f, "pixelWidth")
        set h to my getImage(f, "pixelHeight")
       
        -------------------Preferences for reset-----------------------
       
        set appviewprefs to properties of view preferences
        set defpre to item 1 of every document preset whose name is "[Default]"
        set defprop to properties of item 1 of defpre
       
        -------------------New Document with image placed-----------------------
       
        --setup document (height, width, margin-top, margin-right, margin-bottom, margin-left, bleed, columns, facing?, num pages)
        my docSetup(h, w, 0, 0, 0, 0, 0, 1, false, 1)
       
        set exportdoc to make new document with properties {document preset:"[Default]"}
        set myp to active page of layout window 1
        place f on myp
       
        -------------------------------Reset----------------------------------
       
        set properties of view preferences to appviewprefs
        set properties of item 1 of defpre to defprop
       
    on error
        display dialog "Please choose an image file"
        return -128
    end try
end tell
-------------------------------Functions----------------------------------
--gets image info via command line
on getImage(fle, s)
    tell application "Finder"
        try
            set filePosixPath to quoted form of POSIX path of fle
            set infoString to do shell script ("sips -g " & s & " " & filePosixPath) as string
        end try
        set d to word 2 of paragraph 2 of infoString as number
        return d
    end tell
end getImage
--set document units
on docSetup(h, w, mt, mr, mb, ml, b, c, fp, tp)
    tell application "Adobe InDesign CC 2018"
        set properties of view preferences to {horizontal measurement units:pixels, vertical measurement units:pixels, ruler origin:spread origin}
        set properties of item 1 of every document preset whose name is "[Default]" to {document bleed bottom offset:b, document bleed uniform size:true, column count:c, bottom:mb, left:ml, right:mr, top:mt, pages per document:tp, page height:h, facing pages:fp, page width:w, start page number:1}
    end tell
end docSetup

I wouldn’t hold my breath waiting when ID will be able to do this. Agree with Derek, it would hardly be useful for InDesign.

You need to create a new doc at first, one way or another.

While the second - fitting page to placed object - is doable, with Page tool, or the script.

Read this article, and find Peter Kahrel’s comment with script provided below it.

Notice Peter posted two versions of the script!

I’m intrigued to know why the facility you describe would be useful.