[25.3.1 macOS]Photoshopで作成したpsd画像に日本語のクリッピングパスが使用されていると、Illustratorに配置してもクリッピングパスが反映されない

自分用に作った問題のあるpsd画像のクリッピングパス名を変換するapplescriptです。ファイルを添付できなかったのでコードをペーストしました。利用する場合はスクリプトエディタにペーストしてください。

--イラストレーターに配置されたpsd画像のクリッピングパス名が欧文英数字スペース以外の場合、Photoshopでクリッピングパス名をPath 1に変換して上書き保存するスクリプトです。
--使い方：イラストレーターで配置したpsd画像に問題のあるファイルを開いた後にこのスクリプトを実行してください。
--念の為、対象データのバックアップを行ってから使用してください。このスクリプトを利用した際になにか問題が生じても、当方では一切責任を負えません。

use AppleScript version "2.4"
use framework "Foundation"
use scripting additions

local regularExpression
set regularExpression to (current application's NSRegularExpression's regularExpressionWithPattern:"^[\\x200-9a-zA-Z]+$" options:0 |error|:(missing value))

tell application id "com.adobe.illustrator"
	try
		set placedItemFIlePaths to file path of placed items of current document whose (name ends with ".psd")
	on error massage number n
		activate
		display alert massage
		return n
	end try
	if (count placedItemFIlePaths) is 0 then return 0
end tell

tell application id "com.adobe.photoshop"
	set versionStr to current application's NSString's stringWithString:version
	if (round ((versionStr's floatValue()) * 10)) > 222 then
		activate
		display alert "Photoshopのバージョンが v22.2以下で動作します。"
		return 0
	end if
	repeat with processingFilePath in placedItemFIlePaths
		repeat 1 times
			open file processingFilePath
			tell current document
				set clippingPath to (path items whose kind is clipping)
				if (count clippingPath) is not 1 then
					close saving no
					exit repeat
				end if
				set clippingPathName to name of item 1 of clippingPath
				set matcheNum to (regularExpression's numberOfMatchesInString:clippingPathName options:0 range:{location:0, |length|:count clippingPathName})
				if matcheNum is 0 then
					repeat with i from 1 to 10
						if ("Path " & i) is not in name of path items then
							set name of item 1 of clippingPath to "Path " & i
							exit repeat
						end if
					end repeat
					save
				end if
				close saving no
			end tell
		end repeat
	end repeat
end tell

わたしのところのCatalinaでも再現しました。しかしWindows10は大丈夫でした。一連のmac版におけるUnicodeの取り扱いに絡むものでしょう(^-^;

Windows10pro (20H2) ですが，クリッピングパスは適用されました。

Mac版だけなのかしら…^^;;

macOS 10.14.6 Mojave

すべて再現しました。かなり深刻なバグですね…。

UserVoiceへの投稿をお願いできますか？ 日本語で大丈夫です。

UserVoice - Illustrator (デスクトップ版) バグ